(AutoIt) S3 List Parts

This operation lists the parts that have been uploaded for a specific multipart upload.

This operation must include the upload ID, which you obtain by sending the initiate multipart upload request. This request returns a maximum of 1000 uploaded parts. The default number of parts returned is 1000 parts. You can restrict the number of parts returned by specifying the max-parts request parameter. If your multipart upload consists of more than 1000 parts, the response returns an IsTruncated field with the value of true, and a NextPartNumberMarker element. In subsequent List Parts requests you can include the part-number-marker query string parameter and set its value to the NextPartNumberMarker field value from the previous response.

This example sends GET request that looks like this:

GET /example-object?uploadId=XXBsb2FkIElEIGZvciBlbHZpbmcncyVcdS1tb3ZpZS5tMnRzEEEwbG9hZA&max-parts=100&part-number-marker=1 HTTP/1.1
Host: example-bucket.s3.amazonaws.com
Date: Mon, 1 Nov 2010 20:34:56 GMT
Authorization: authorization string

The following is a sample response:

HTTP/1.1 200 OK
x-amz-id-2: Uuag1LuByRx9e6j5Onimru9pO4ZVKnJ2Qz7/C1NPcfTWAtRPfTaOFg==
x-amz-request-id: 656c76696e6727732072657175657374
Date: Mon, 1 Nov 2010 20:34:56 GMT
Content-Length: 985
Connection: keep-alive
Server: AmazonS3

<?xml version="1.0" encoding="UTF-8"?>
<ListPartsResult xmlns="http://s3.amazonaws.com/doc/2006-03-01/">
  <Bucket>example-bucket</Bucket>
  <Key>example-object</Key>
  <UploadId>XXBsb2FkIElEIGZvciBlbHZpbmcncyVcdS1tb3ZpZS5tMnRzEEEwbG9hZA</UploadId>
  <Initiator>
      <ID>arn:aws:iam::111122223333:user/some-user-11116a31-17b5-4fb7-9df5-b288870f11xx</ID>
      <DisplayName>umat-user-11116a31-17b5-4fb7-9df5-b288870f11xx</DisplayName>
  </Initiator>
  <Owner>
    <ID>75aa57f09aa0c8caeab4f8c24e99d10f8e7faeebf76c078efc7c6caea54ba06a</ID>
    <DisplayName>someName</DisplayName>
  </Owner>
  <StorageClass>STANDARD</StorageClass>
  <PartNumberMarker>1</PartNumberMarker>
  <NextPartNumberMarker>3</NextPartNumberMarker>
  <MaxParts>2</MaxParts>
  <IsTruncated>true</IsTruncated>
  <Part>
    <PartNumber>2</PartNumber>
    <LastModified>2010-11-10T20:48:34.000Z</LastModified>
    <ETag>"7778aef83f66abc1fa1e8477f296d394"</ETag>
    <Size>10485760</Size>
  </Part>
  <Part>
    <PartNumber>3</PartNumber>
    <LastModified>2010-11-10T20:48:33.000Z</LastModified>
    <ETag>"aaaa18db4cc2f85cedef654fccc4a4x8"</ETag>
    <Size>10485760</Size>
  </Part>
</ListPartsResult>

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

; This example requires the Chilkat API to have been previously unlocked.
; See Global Unlock Sample for sample code.

; Other S3 Multipart Upload Examples:
; Initiate Multipart Upload
; S3 Upload Parts
; Complete Multipart Upload
; Abort Multipart Upload

; When the multipart upload was initiated, an UploadId was provided in the XML response, and 
; we saved it to a file.  We'll get the upload ID from there..

$oXmlInit = ObjCreate("Chilkat.Xml")
Local $bSuccess = $oXmlInit.LoadXmlFile("s3_multipart_uploads/initiate.xml")
If ($bSuccess <> True) Then
    ConsoleWrite("Did not find the initiate.xml XML file." & @CRLF)
    Exit
EndIf

Local $sUploadId = $oXmlInit.GetChildContent("UploadId")
ConsoleWrite("UploadId = " & $sUploadId & @CRLF)

$oRest = ObjCreate("Chilkat.Rest")

; Connect to the Amazon AWS REST server.
Local $bTls = True
Local $iPort = 443
Local $bAutoReconnect = True
$bSuccess = $oRest.Connect("s3.amazonaws.com",$iPort,$bTls,$bAutoReconnect)

; ----------------------------------------------------------------------------
; Important: For buckets created in regions outside us-east-1,
; there are three important changes that need to be made.
; See Working with S3 Buckets in Non-us-east-1 Regions for the details.
; ----------------------------------------------------------------------------

; Provide AWS credentials for the REST call.
$oAuthAws = ObjCreate("Chilkat.AuthAws")
$oAuthAws.AccessKey = "AWS_ACCESS_KEY"
$oAuthAws.SecretKey = "AWS_SECRET_KEY"
$oAuthAws.ServiceName = "s3"

$bSuccess = $oRest.SetAuthAws($oAuthAws)

; Set the bucket name via the HOST header.
; In this case, the bucket name is "chilkat100".
$oRest.Host = "chilkat100.s3.amazonaws.com"

; Add the query parameters.
$oRest.AddQueryParam("uploadId",$sUploadId)
$oRest.AddQueryParam("max-parts","100")
$oRest.AddQueryParam("part-number-marker","0")

; Our ObjectName in this case is "somethingBig.zip".
Local $sResponseXml = $oRest.FullRequestNoBody("GET","/somethingBig.zip")
If ($oRest.LastMethodSuccess <> True) Then
    ConsoleWrite($oRest.LastErrorText & @CRLF)
    Exit
EndIf

; When successful, the S3 Storage service will respond with a 200 response code,
; with an XML body.  
If ($oRest.ResponseStatusCode <> 200) Then
    ; Examine the request/response to see what happened.
    ConsoleWrite("response status code = " & $oRest.ResponseStatusCode & @CRLF)
    ConsoleWrite("response status text = " & $oRest.ResponseStatusText & @CRLF)
    ConsoleWrite("response header: " & $oRest.ResponseHeader & @CRLF)
    ConsoleWrite("response body: " & $sResponseXml & @CRLF)
    ConsoleWrite("---" & @CRLF)
    ConsoleWrite("LastRequestStartLine: " & $oRest.LastRequestStartLine & @CRLF)
    ConsoleWrite("LastRequestHeader: " & $oRest.LastRequestHeader & @CRLF)
EndIf

$oXml = ObjCreate("Chilkat.Xml")
$oXml.LoadXml($sResponseXml)

ConsoleWrite($oXml.GetXml() & @CRLF)
ConsoleWrite("----" & @CRLF)

; To iterate over the parts in the response, navigate to the 1st "Part" node
; and then iterate over siblings until there are no more.
Local $oPart = $oXml.FindChild("Part")
If ($oXml.LastMethodSuccess = False) Then
    ConsoleWrite("No parts exist." & @CRLF)
    Exit
EndIf

Local $bHasMoreParts = True
While $bHasMoreParts = True
    ConsoleWrite("PartNumber: " & $oPart.GetChildContent("PartNumber") & @CRLF)
    ConsoleWrite("LastModified: " & $oPart.GetChildContent("LastModified") & @CRLF)
    ConsoleWrite("ETag: " & $oPart.GetChildContent("ETag") & @CRLF)
    ConsoleWrite("Size: " & $oPart.GetChildContent("Size") & @CRLF)
    ConsoleWrite("----" & @CRLF)

    ; Advance to the next sibling until we run out.
    $bHasMoreParts = $oPart.NextSibling2()
Wend