(AutoIt) PKCS7 Sign Text using RSA 2048, SHA256, Base64 Output

Demonstrates how to sign text using 2048-bit RSA with SHA256, producing PKCS#7 output in Base64. The certificate w/ private key used for signing is loaded from a .p12/.pfx file.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

; This example requires the Chilkat API to have been previously unlocked.
; See Global Unlock Sample for sample code.

$oCert = ObjCreate("Chilkat.Cert")

; Load the cert and private key.  Whatever the private key happens to be,
; such as RSA or ECC, then Chilkat will use it.  If the private key is 
; a 2048-bit RSA key, then that's what will be used..
Local $bSuccess = $oCert.LoadPfxFile("qa_data/pfx/myCertAndKey.p12","password")
If ($bSuccess <> True) Then
    ConsoleWrite($oCert.LastErrorText & @CRLF)
    Exit
EndIf

$oCrypt = ObjCreate("Chilkat.Crypt2")

$bSuccess = $oCrypt.SetSigningCert($oCert)
If ($bSuccess <> True) Then
    ConsoleWrite($oCrypt.LastErrorText & @CRLF)
    Exit
EndIf

; Use SHA-256
$oCrypt.HashAlgorithm = "sha256"

; Hash the utf-8 byte representation of the string
$oCrypt.Charset = "utf-8"

; Return the result in base64
$oCrypt.EncodingMode = "base64"

; Sign some text..
Local $sTextToSign = "This is the text to be hashed and signed."
Local $sigBase64 = $oCrypt.OpaqueSignStringENC($sTextToSign)
If ($oCrypt.LastMethodSuccess <> True) Then
    ConsoleWrite($oCrypt.LastErrorText & @CRLF)
    Exit
EndIf

ConsoleWrite($sigBase64 & @CRLF)

; The result:
; MIIS2wYJKoZIhvcNAQc ... zGeeY4Oxg==