|
|
(AutoIt) PDF Sign Under Existing Signature
This example explains how sign a previously-signed PDF and place the signature appearance below the existing signature.
Note: This example requires Chilkat v9.5.0.85 or greater.
; This example requires the Chilkat API to have been previously unlocked.
; See Global Unlock Sample for sample code.
$oPdf = ObjCreate("Chilkat.Pdf")
; Load a PDF to be signed.
Local $bSuccess = $oPdf.LoadFile("qa_data/pdf/sign_testing_4/hello_signed.pdf")
If ($bSuccess = False) Then
ConsoleWrite($oPdf.LastErrorText & @CRLF)
Exit
EndIf
; The PDF we'll be signing already has a signature added in Adobe Acrobat DC.
; It looks like this:
; (Notice the Adobe background logo, which is commonly what you'll see when a signature
; is created by Adobe Acrobat. Chilkat (obviously) does not create signatures using the Adobe
; logo because it would be a copyright violation.)
; Options for signing are specified in JSON.
$oJson = ObjCreate("Chilkat.JsonObject")
; In most cases, the signingCertificateV2 and signingTime attributes are required.
$oJson.UpdateInt("signingCertificateV2",1)
$oJson.UpdateInt("signingTime",1)
; To put our new signature underneath the existing signature, we have to specify the page
; where the existing signature is found, and then we can specify "under" for the "appearance.y"
$oJson.UpdateInt("page",1)
$oJson.UpdateString("appearance.y","under")
$oJson.UpdateString("appearance.fontScale","10.0")
$oJson.UpdateString("appearance.text[0]","Reason: Agreement Accepted by John")
$oJson.UpdateString("appearance.text[1]","Date: current_dt")
; Load the signing certificate. (Use your own certificate.)
$oCert = ObjCreate("Chilkat.Cert")
$bSuccess = $oCert.LoadPfxFile("qa_data/pfx/myPdfSigningCert.pfx","secret")
If ($bSuccess = False) Then
ConsoleWrite($oCert.LastErrorText & @CRLF)
Exit
EndIf
; Tell the pdf object to use the certificate for signing.
$bSuccess = $oPdf.SetSigningCert($oCert)
If ($bSuccess = False) Then
ConsoleWrite($oPdf.LastErrorText & @CRLF)
Exit
EndIf
; Note: When adding an additional signature to a PDF, the existing signatures
; are validated, and this includes validating the certificates previously used to
; create the existing signatures. (A signature typically embeds the signing certs.)
; In some cases, the certificates and/or certs in the chain of authentication for
; existing signatures are not present, and are not available on the current system.
; In this case, you can skip the validation by setting this keyword in UncommonOptions:
$oPdf.UncommonOptions = "NO_VERIFY_CERT_SIGNATURES"
$bSuccess = $oPdf.SignPdf($oJson,"qa_output/hello_signed.pdf")
If ($bSuccess = False) Then
ConsoleWrite($oPdf.LastErrorText & @CRLF)
Exit
EndIf
ConsoleWrite("The PDF has been successfully cryptographically signed." & @CRLF)
; Here's a screenshot of the 2nd signature positioned under the 1st in Adobe Acrobat:
|
