(AutoIt) Export a Private Key from an MS Storage Provider

Demonstrates how to export a private key from a Microsoft Storage Provider.

Note: This example requires Chilkat v9.5.0.83 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

; This example requires Chilkat v9.5.0.83 or greater.

; We'll export a certificate's private key from the MS storage provider.
; It is assumed the certificate + private key is already installed on the Windows system.
; The export does not remove the key from the Windows storage provider.

; First, let's get a certificate in one of the many ways we can do it.
; (I ran certmgr.msc, opened a certificate, and noted it's thumbprint.)
$oCert = ObjCreate("Chilkat.Cert")
Local $bSuccess = $oCert.LoadByThumbprint("ea5a129c1919a52d238ee28d9f3a8f345b768388","hex")
If ($bSuccess = False) Then
    ConsoleWrite($oCert.LastErrorText & @CRLF)
    Exit
EndIf

ConsoleWrite("Found: " & $oCert.SubjectDN & @CRLF)

; First export the private key the easy way.
Local $oPrivKey = $oCert.ExportPrivateKey()
If ($oCert.LastMethodSuccess = False) Then
    ConsoleWrite($oCert.LastErrorText & @CRLF)
    Exit
EndIf

; OK.. we have the private key.  Do whatever we want with it..

; -------------------------------------------------------------
; Now let's export in a more roundabout way by getting information about the 
; storage provider and key name and then we'll export completely independent
; of the certificate.
; 
; Remember: The private key is not contained within the certificate.  An X.509 certificate
; embeds the public key, but the counterpart private key is stored elsewhere, such
; as in a .pfx/.p12, or as in this case, in the Windows "protected store", or perhaps on
; a smartcard or hardware token.  (But a private key stored on a smartcard or token cannot
; be exported.  It must remain on the hardware.)
; 

Local $storageProvider = $oCert.CspName
Local $sKeyName = $oCert.KeyContainerName

ConsoleWrite("Information about the certificate's private key:" & @CRLF)
ConsoleWrite("Storage Provider: " & $storageProvider & @CRLF)
ConsoleWrite("Key Name: " & $sKeyName & @CRLF)

; Export using just the name of the storage provider and key.
$oKeyCon = ObjCreate("Chilkat.KeyContainer")
$oPrivKey2 = ObjCreate("Chilkat.PrivateKey")
Local $bSilentFlag = False
$bSuccess = $oKeyCon.ExportKey($sKeyName,$storageProvider,$bSilentFlag,$oPrivKey2)
If ($bSuccess = False) Then
    ConsoleWrite($oKeyCon.LastErrorText & @CRLF)
    Exit
EndIf

; OK.. we have the private key in privKey2.  Do whatever we want with it..
; Perhaps we save as encrypted PKCS8 PEM.
$bSuccess = $oPrivKey2.SavePkcs8EncryptedPemFile("myPassword","qa_output/privKey2.pem")
If ($bSuccess = False) Then
    ConsoleWrite($oPrivKey2.LastErrorText & @CRLF)
    Exit
EndIf

ConsoleWrite("Success." & @CRLF)