(AutoIt) Manage Bucket Storage Class

See more Google Cloud Storage Examples

Demonstrates how to manage a bucket's default storage class.

See Cloud Storage Classes for information about storage classes.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

; This example requires the Chilkat API to have been previously unlocked.
; See Global Unlock Sample for sample code.

; This example uses a previously obtained access token having permission for the 
; scope "https://www.googleapis.com/auth/cloud-platform"

; In this example, Get Google Cloud Storage OAuth2 Access Token, 
; the service account access token was saved to a text file.  This example fetches the access token from the file..
$oSbToken = ObjCreate("Chilkat.StringBuilder")
$oSbToken.LoadFile("qa_data/tokens/googleCloudStorageAccessToken.txt","utf-8")

; ---- Step 1
; Create the JSON body of the PUT request that will be sent.

; {
;   "storageClass": "[STORAGE_CLASS]"
; }
; 

$oJson = ObjCreate("Chilkat.JsonObject")
; Be careful if using the "regional" storage class.  See the note below about the 400 error response.
$oJson.UpdateString("storageClass","nearline")

; ---- Step 2
; Send a PUT equivalent to this curl command

; curl -X PUT --data-binary @[JSON_FILE_NAME].json \
;     -H "Authorization: Bearer [OAUTH2_TOKEN]" \
;     -H "Content-Type: application/json" \
;     "https://www.googleapis.com/storage/v1/b/[BUCKET_NAME]?fields=storageClass"

$oHttp = ObjCreate("Chilkat.Http")
$oHttp.AuthToken = $oSbToken.GetAsString()

$oHttp.SetUrlVar("bucket_name","chilkat-ocean")
Local $sUrl = "https://www.googleapis.com/storage/v1/b/{$bucket_name}?fields=storageClass"
Local $oResp = $oHttp.PText("PUT",$sUrl,$oJson.Emit(),"utf-8","application/json",False,False)
If ($oHttp.LastMethodSuccess = False) Then
    ConsoleWrite($oHttp.LastErrorText & @CRLF)
    Exit
EndIf

Local $iResponseCode = $oResp.StatusCode
If ($iResponseCode = 401) Then
    ConsoleWrite($oResp.BodyStr & @CRLF)
    ConsoleWrite("If invalid credentials, then it is likely the access token expired." & @CRLF)
    ConsoleWrite("Your app should automatically fetch a new access token and re-try." & @CRLF)

    Exit
EndIf

; On my first try at running this code, I received the following error response:
; Response code: 400
; Response body
; {
;  "error": {
;   "errors": [
;    {
;     "domain": "global",
;     "reason": "invalid",
;     "message": "The combination of locationConstraint and storageClass you provided is not supported for your project"
;    }
;   ],
;   "code": 400,
;   "message": "The combination of locationConstraint and storageClass you provided is not supported for your project"
;  }
; }
; 

; This was because my storage location was a Multi-regional location, and I tried to assign the "regional" storage class,
; which is not allowed. 

ConsoleWrite("Response code: " & $iResponseCode & @CRLF)
ConsoleWrite("Response body" & @CRLF)
ConsoleWrite($oResp.BodyStr & @CRLF)

; A response code = 200 indicates success, and the response body contains the JSON
; 
; Response code: 200
; Response body
; {
;  "storageClass": "NEARLINE"
; }
;