(AutoIt) Dropbox Content Hash

Demonstrates how to compute the Dropbox content_hash of a file. (This is the "content_hash" found in the Dropbox FileMetadata object.

Note: This example requires Chilkat v9.5.0.79 or greater because it uses the fac.ReadBlockBd method.

For more information, see https://www.dropbox.com/developers/reference/content-hash

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

; This example requires the Chilkat API to have been previously unlocked.
; See Global Unlock Sample for sample code.

$oCrypt = ObjCreate("Chilkat.Crypt2")

; To calculate the content_hash of a file:
; Split the file into blocks of 4 MB (4,194,304 or 4 * 1024 * 1024 bytes). The last block (if any) may be smaller than 4 MB.
; Compute the hash of each block using SHA-256.
; Concatenate the hash of all blocks in the binary format to form a single binary string.
; Compute the hash of the concatenated string using SHA-256. Output the resulting hash in hexadecimal format.

$oCrypt.HashAlgorithm = "sha256"
$oCrypt.EncodingMode = "hex_lower"

; We're going to calculate the content_hash for the Milky Way JPG image linked here:  https://www.dropbox.com/developers/reference/content-hash

$oFac = ObjCreate("Chilkat.FileAccess")
$oBd = ObjCreate("Chilkat.BinData")
$oBdHashes = ObjCreate("Chilkat.BinData")

Local $bSuccess = $oFac.OpenForRead("qa_data/jpg/milky-way-nasa.jpg")
If ($bSuccess = False) Then
    ConsoleWrite($oFac.LastErrorText & @CRLF)
    Exit
EndIf

Local $iBlockSize = 4194304
Local $iNumBlocks = $oFac.GetNumBlocks($iBlockSize)

Local $i = 0
While ($i < $iNumBlocks)
    ; Read the next 4MB block into bd.
    $oBd.Clear()
    $bSuccess = $oFac.ReadBlockBd($i,$iBlockSize,$oBd)

Local $sHashHex = $oCrypt.HashBdENC($oBd)
    ConsoleWrite($i & ": " & $sHashHex & @CRLF)
    $oBdHashes.AppendEncoded($sHashHex,"hex_lower")

    $i = $i + 1
Wend

$oFac.FileClose 

; Hash the concatenated SHA-256 hashes.
Local $sContent_hash = $oCrypt.HashBdENC($oBdHashes)
ConsoleWrite("content_hash = " & $sContent_hash & @CRLF)