(Classic ASP) XML Document References

This example demonstrates the fact that the entire XML document remains in memory if at least one node is referenced. (It does not need to be the root node.)

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = Server.CreateObject("Chilkat.Xml")

success = xml.LoadXml("<a><b>BBB</b><c>CCC</c></a>")

Response.Write "<pre>" & Server.HTMLEncode( xml.GetXml()) & "</pre>"

' We have the following XML stored in memory:

' 	<?xml version="1.0" encoding="utf-8"?>
' 	<a>
' 	    <b>BBB</b>
' 	    <c>CCC</c>
' 	</a>

' Get a reference to the 1st child.
' xB is a Chilkat.Xml
Set xB = xml.GetChild(0)

' Re-load "xml" with an entirely new document:
success = xml.LoadXml("<z><x>XXX</x></z>")

' What happens to xB?
' The answer is nothing.  xB still points ot the "b" node in the original document, and the entire
' original document remains in memory.  We now have two XML documents in memory.

Response.Write "<pre>" & Server.HTMLEncode( xB.GetXml()) & "</pre>"

' output is:

'     <b>BBB</b>

' Make xB reference the root node of its document:
xB.GetRoot2 
Response.Write "<pre>" & Server.HTMLEncode( xB.GetXml()) & "</pre>"

' You can see here that the entire original XML document is still available
' because at least one node in the XML is referenced by a variable.
' The output is:

'     <?xml version="1.0" encoding="utf-8"?>
'     <a>
'         <b>BBB</b>
'         <c>CCC</c>
'     </a>

' We can also see that "xml" contains an entirely new XML document:
Response.Write "<pre>" & Server.HTMLEncode( xml.GetXml()) & "</pre>"

'     <?xml version="1.0" encoding="utf-8"?>
'     <z>
'         <x>XXX</x>
'     </z>
' 


%>
</body>
</html>