(Classic ASP) WebSocket over TLS

Establishing a WebSocket connection over TLS is exactly the same as for TCP, except for a few arguments passed to the Connect method.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------
' A WebSocket connection begins life as an HTTP GET request containing a few special header fields,
' such as "Upgrade: websocket".   

' Your application will use the Chilkat Rest class to send the initial HTTP GET.  This allows you
' to use the full capability of the Chilkat Rest class to customize the GET for any particular situation.
' For example:
' 
'   - If custom HTTP request header fields must be added.
'   - If authentication is required, such as OAuth2, OAuth1, Basic HTTP Auth, etc.
'   - If HTTPS, SSH Tunneling, Proxies (HTTP or SOCKS), or other advanced connection or TLS features are required.
' 

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = Server.CreateObject("Chilkat.Rest")
' ------------------------------------------------------------------
' To use TLS, connect to the TLS port (typically 443) and tell the rest.Connect method
' that it's a TLS connection.
' ------------------------------------------------------------------
bUseTls = 1
success = rest.Connect("someserver.com",443,bUseTls,0)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rest.LastErrorText) & "</pre>"
    Response.End
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.WebSocket")
set ws = Server.CreateObject("Chilkat.WebSocket")

' Tell the WebSocket to use this connection.
success = ws.UseConnection(rest)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ws.LastErrorText) & "</pre>"
    Response.End
End If

' Add the standard WebSocket open handshake headers that will be needed.
' (This adds the required HTTP request headers to the rest object.)
success = ws.AddClientHeaders()

' Add any additional headers that might be desired.
' Two common WebSocketSpecific headers are "Sec-WebSocket-Protocol" and "Origin".
success = rest.AddHeader("Sec-WebSocket-Protocol","x-something")
success = rest.AddHeader("Origin","http://someserver.com")

' Do the open handshake.
responseBody = rest.FullRequestNoBody("GET","/something")
If (rest.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rest.LastErrorText) & "</pre>"
    Response.End
End If

' If successful, the HTTP response status code should be 101,
' and the response body will be empty. (If it failed, we'll have a look
' at the response body..)
statusCode = rest.ResponseStatusCode
Response.Write "<pre>" & Server.HTMLEncode( "Response status code: " & statusCode) & "</pre>"

If (statusCode <> 101) Then
    Response.Write "<pre>" & Server.HTMLEncode( responseBody) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( "-- Failed because of unexpected response status code.") & "</pre>"
    Response.End
End If

' We have the expected 101 response, so let's now validate the 
' contents of the response, such as the value sent by the server in the
' Sec-WebSocket-Accept header. 
success = ws.ValidateServerHandshake()
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ws.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "WebSocket connection successful.") & "</pre>"

' The application may now begin sending and receiving frames on the WebSocket connection.
' (At this point, we're done with the rest object...)

%>
</body>
</html>