(Classic ASP) Unzip Binary File to Stream

Demonstrates how to unzip a large binary file to a stream to allow the application to process the uncompressed bytes chunk by chunk.

Note: This example requires Chilkat v9.5.0.67 or greater.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This requires the Chilkat Zip API to have been previously unlocked.
' See Unlock Chilkat Zip for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Zip")
set zip = Server.CreateObject("Chilkat.Zip")

' First open a .zip.
success = zip.OpenZip("qa_data/zips/big.zip")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( zip.LastErrorText) & "</pre>"
    Response.End
End If

' Get the entry to be unzipped to a stream..
' entry is a Chilkat.ZipEntry
Set entry = zip.GetEntryByIndex(0)
If (zip.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( zip.LastErrorText) & "</pre>"
    Response.End
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Stream")
set dataStream = Server.CreateObject("Chilkat.Stream")

' unzipTask is a Chilkat.Task
Set unzipTask = entry.UnzipToStreamAsync(dataStream)
If (entry.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( entry.LastErrorText) & "</pre>"

    Response.End
End If

' Start the background unzip thread.
success = unzipTask.Run()

' We'll read the uncompressed data chunk-by-chunk and write to an output file.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = Server.CreateObject("Chilkat.FileAccess")
success = fac.OpenForWrite("qa_output/out.dat")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( fac.LastErrorText) & "</pre>"

    Response.End
End If

' Read the stream.  (this is reading the unzipped file data)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = Server.CreateObject("Chilkat.BinData")
Do While dataStream.EndOfStream <> 1
    ' Get the next chunk of decompressed bytes.
    success = dataStream.ReadBd(bd)
    ' Do something with it..
    ' In this simple example, we'll just write to the file.
    success = fac.FileWriteBd(bd,0,0)
    ' Clear for the next read.
    success = bd.Clear()
Loop

fac.FileClose 

Response.Write "<pre>" & Server.HTMLEncode( "Success.") & "</pre>"

%>
</body>
</html>