(Classic ASP) Socket Convert Existing TCP Connection to SSL/TLS

Demonstrates the Chilkat Socket ConvertToSsl method.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Socket")
set sock = Server.CreateObject("Chilkat.Socket")

' --------------------------------------------------------------------
' This example uses the public TCP/TLS echo service at https://tcpbin.com/
' --------------------------------------------------------------------

' The echo server at tcpbin.com expects to receive TCP connections on port 4242, and TLS connections on port 4243.
' We could simply connect to port 4243 using TLS like this.
' However, further below, this example shows how to initially make a TCP connection, and then convert the connection to TLS.
useTls = 1
port = 4243
maxWaitMs = 5000
success = sock.Connect("tcpbin.com",port,useTls,maxWaitMs)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( sock.LastErrorText) & "</pre>"
    Response.End
End If

' OK, we have a TLS connection.
' Note: The server chooses the TLS protocol version. 
' We can see the version of the TLS connection that was established:
Response.Write "<pre>" & Server.HTMLEncode( "TLS version: " & sock.TlsVersion) & "</pre>"

success = sock.Close(maxWaitMs)

' ---------------------------------------------------------------------
' Now we'll do the same, except first we connect to port 4243 using TCP,
' and then convert the connection to TLS.
' 
' This may seem pointless, and it is for the case w/ this server.  However, there could be situations
' where you're interacting with a server of some kind where there is a need to convert to/from TLS.
' (This is common internal to many protocols, such as SMTP, IMAP, FTP, etc., and it is often called "explicit" SSL/TLS)

' Connect again, except this time useTls is 0, so we only have a simple TCP connection after this call.
useTls = 0
success = sock.Connect("tcpbin.com",port,useTls,maxWaitMs)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( sock.LastErrorText) & "</pre>"
    Response.End
End If

' Convert the existing TCP connection to TLS.
' (The method name uses "SSL" because long ago, at the time of initial development, TLS 1.0 did not yet exist.)
success = sock.ConvertToSsl()
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( sock.LastErrorText) & "</pre>"
    Response.End
End If

' OK, we now have a TLS connection.
' Again, we can see the TLS version:
Response.Write "<pre>" & Server.HTMLEncode( "TLS version: " & sock.TlsVersion) & "</pre>"

success = sock.Close(maxWaitMs)

%>
</body>
</html>