Classic ASP
Send Email with a vCard

Demonstrates how to create a simple email, attach a vcard, and send it.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  The mailman object is used for sending and receiving email.
set mailman = Server.CreateObject("Chilkat.MailMan")

'  Set the SMTP server.
mailman.SmtpHost = "smtp.chilkatsoft.com"

'  Set the SMTP login/password (if required)
mailman.SmtpUsername = "myUsername"
mailman.SmtpPassword = "myPassword"

'  Create a new email object
set email = Server.CreateObject("Chilkat.Email")

email.Subject = "This is a vcard test"
email.Body = "This is a vcard test"
email.From = "Chilkat Admin <admin@chilkatsoft.com>"
success = email.AddTo("Chilkat Support","support@chilkatsoft.com")
'  To add more recipients, call AddTo, AddCC, or AddBcc once per recipient.

'  A vCard is an email attachment having a Content-Type = "text/x-vcard".
'  Call AddStringAttachment to add a vcard from an in-memory string.
'  The filename should have a ".vcf" file extension.  Chilkat will automatically
'  recognize it and set the content-type to "text/x-vcard";

'  Your application is responsible for providing the vcard formatted string.  For example:
'  See http://en.wikipedia.org/wiki/VCard
'  
'  begin:vcard
'  fn:Matt Smith
'  n:Smith;Matt
'  org:Chilkat Software, Inc.
'  tel;work:630-784-9670
'  url:http://www.chilkatsoft.com
'  version:2.1
'  end:vcard

vcard = "begin:vcard ..."
success = email.AddStringAttachment("admin.vcf",vcard)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( email.LastErrorText) & "</pre>"
    Response.End
End If

'  Call SendEmail to connect to the SMTP server and send.
'  The connection (i.e. session) to the SMTP server remains
'  open so that subsequent SendEmail calls may use the
'  same connection.  
success = mailman.SendEmail(email)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( mailman.LastErrorText) & "</pre>"
    Response.End
End If

'  Some SMTP servers do not actually send the email until 
'  the connection is closed.  In these cases, it is necessary to
'  call CloseSmtpConnection for the mail to be  sent.  
'  Most SMTP servers send the email immediately, and it is 
'  not required to close the connection.  We'll close it here
'  for the example:
success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( "Connection to SMTP server not closed cleanly.") & "</pre>"
End If

Response.Write "<pre>" & Server.HTMLEncode( "Mail with vCard Sent!") & "</pre>"

%>
</body>
</html>