(Classic ASP) Send Signed Email using PFX File

Demonstrates how to send a signed email using a digital certificate w/ private key stored in a PFX file.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for sending and receiving email.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = Server.CreateObject("Chilkat.MailMan")

' Set the SMTP server.
mailman.SmtpHost = "smtp.mymailserver.com"

' Create a new email object
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = Server.CreateObject("Chilkat.Email")

email.Subject = "This email is signed"
email.Body = "This is a digitally signed mail"
email.From = "Chilkat Admin <admin@chilkatsoft.com>"
success = email.AddTo("Chilkat Support","support@chilkatsoft.com")

' Indicate that the email should be sent signed.
email.SendSigned = 1

' Tell the mailman to use a PFX file as a source for locating
' the certificate and private key required for signing.
' The certificate chosen for signing will be the one that
' matches the sender's email address, which also has
' a private key.  All intermediate certs in the chain of 
' authentication, up to and including the root, will
' be included in the signature.
success = mailman.AddPfxSourceFile("/pfx_files/chilkatsoft_secret.pfx","secret")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( mailman.LastErrorText) & "</pre>"
    Response.End
End If

' Signed email can be sent in two different ways.  
' In a multipart/signed email, the signature is attached as a separate MIME part.
' In an opaque email (signedData) the content of the email is encapsulated within the signature
' and the email is sent as "application/pkcs7-mime". 
' Either should be fine, but some receiving systems might require one or the other..
mailman.OpaqueSigning = 0

' Send a signed email.
success = mailman.SendEmail(email)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( mailman.LastErrorText) & "</pre>"
Else
    ' The LastErrorText property provides information
    ' even when successful.
    Response.Write "<pre>" & Server.HTMLEncode( mailman.LastErrorText) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( "Mail Sent!") & "</pre>"
End If


%>
</body>
</html>