(Classic ASP) SFTP Upload with Bandwidth Throttling

Demonstrates how to upload a file to an SSH server in the simplest way with bandwidth throttling. Bandwidth throttling for all SFTP communications can be achieved by simply setting the BandwidthThrottleUp or BandwidthThrottleDown properties. (One limits the transfer rate for uploads, the other for downloads.)

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = Server.CreateObject("Chilkat.SFtp")

' Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 15000
sftp.IdleTimeoutMs = 15000

' Connect to the SSH server.  
' The standard SSH port = 22
' The hostname may be a hostname or IP address.
hostname = "sftp.example.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
End If

' Authenticate with the SSH server.  Chilkat SFTP supports
' both password-based authenication as well as public-key
' authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
End If

' After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
End If

' Limit the transfer rate (bandwidth throttle) to 64K per second.
sftp.BandwidthThrottleUp = 65536

' Upload from the local file to the SSH server.
' Important -- the remote filepath is the 1st argument,
' the local filepath is the 2nd argument;
remoteFilePath = "hamlet.xml"
localFilePath = "c:/temp/hamlet.xml"

success = sftp.UploadFileByName(remoteFilePath,localFilePath)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "Success.") & "</pre>"

%>
</body>
</html>