(Classic ASP) SFTP Where Did My Upload Go?

This example answers a common question: "I use Chilkat SFTP to upload a file. It says it was successful, but file is not on the server. How do you change directories?";

First, "SFTP" is Secure File Transfer over SSH and has *nothing* to do with FTP (the File Transfer Protocol). It is completely unrelated to FTP. Therefore, FTP concepts such as "current directory", and "binary/ascii transfer modes" don't exist in SFTP.

In SFTP, you authenticate using a user account on the remote server. This could be an actual user account on the server, or a logical user account that exists in the context of the SSH server. In either case, the user account has a home directory. If you open a file on the SSH/SFTP server using only the filename and no path, then your filename will be placed in the user account's home directory. To find out the location of the home directory, call RealPath and pass "." for the directory path. It will return the absolute path of the home directory.

Given that there is no "current directory" concept in SFTP, you must specify either an absolute path or relative path when opening/creating a file that is to be in a directory other than the account's home directory. A relative path is relative to the home directory.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = Server.CreateObject("Chilkat.SFtp")

' Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 5000
sftp.IdleTimeoutMs = 10000

' Connect to the SSH server.  
' The standard SSH port = 22
' The hostname may be a hostname or IP address.
hostname = "sftp.example.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
End If

' Authenticate with the SSH server.  Chilkat SFTP supports
' both password-based authenication as well as public-key
' authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
End If

' After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
End If

' To find the full path of our user account's home directory,
' call RealPath like this:
absPath = sftp.RealPath(".","")
If (sftp.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
Else
    Response.Write "<pre>" & Server.HTMLEncode( absPath) & "</pre>"
End If


%>
</body>
</html>