(Classic ASP) SFTP Simplified Download

Demonstrates how to SFTP download a file by passing a remote filepath to DownloadFileByName.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.SFtp")
set sftp = Server.CreateObject("Chilkat.SFtp")

' Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 15000
sftp.IdleTimeoutMs = 15000

' Connect to the SSH server.  
' The standard SSH port = 22
' The hostname may be a hostname or IP address.
hostname = "sftp.example.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
End If

' Authenticate with the SSH server.  Chilkat SFTP supports
' both password-based authenication as well as public-key
' authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
End If

' After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
End If

' Download the file:

localFilePath = "c:/temp/hamlet.xml"
' Note: The remote filepath may be an absolute filepath,
' a relative filepath, or simply a filename.  
' Relative filepaths are always relative to the home directory
' of the SFTP/SSH user account.  There is no such thing
' as "current remote directory" in the SFTP protocol. 
' A filename with no path implies that the file is located
' in the SFTP user account's home directory.
remoteFilePath = "subdir1/subdir2/hamlet.xml"
success = sftp.DownloadFileByName(remoteFilePath,localFilePath)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( sftp.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "Success.") & "</pre>"

%>
</body>
</html>