(Classic ASP) S3 - Working with Buckets in a Region

Demonstrates how to work with S3 buckets located in a particular region.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' When usig the REST class to access an S3 bucket that has been created in a particular region,
' there are three important things to remember:
' 
' 1) Connect to the domain that includes the region.  For example, instead of connecting to
'    "s3.amazonaws.com", connect to "s3.eu-central-1.amazonaws.com" if your bucket is in the EU Frankfurt region.
'    See http://docs.aws.amazon.com/general/latest/gr/rande.html#s3_region   for a list of S3 region domains (endpoints)
' 
' 2) Set the AuthAws.Region property equal to the region, such as "eu-central-1".
' 
' 3) Include the region in request's Host header.
' 

' This example will upload to a bucket in the eu-central-1 region.
' 
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = Server.CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("s3.eu-central-1.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = Server.CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"
authAws.Region = "eu-central-1"
success = rest.SetAuthAws(authAws)

' Set the bucket name via the HOST header.
' In this case, the bucket name is "chilkateufrankfurt" (which was created in the eu-central-1 region)
rest.Host = "chilkateufrankfurt.s3.eu-central-1.amazonaws.com"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set fileData = Server.CreateObject("Chilkat.BinData")
success = fileData.LoadFile("qa_data/jpg/starfish.jpg")

' Upload the file to Amazon S3.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set responseBody = Server.CreateObject("Chilkat.StringBuilder")
success = rest.FullRequestBd("PUT","/starfish.jpg",fileData,responseBody)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rest.LastErrorText) & "</pre>"
    Response.End
End If

' Did we get a 200 response indicating success?
statusCode = rest.ResponseStatusCode
If (statusCode <> 200) Then
    Response.Write "<pre>" & Server.HTMLEncode( "Error response: " & responseBody.GetAsString()) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( "Status code: " & statusCode & ", Status text: " & rest.ResponseStatusText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "File successfully uploaded.") & "</pre>"

%>
</body>
</html>