(Classic ASP) RSA Signature with Certificate's Private Key from PFX

See more RSA Examples

Demonstrates how to use a certificate's private key from a PFX file to create an RSA signature.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Create an instance of a certificate store object, load a PFX file,
' locate the certificate we need, and use it for signing.
' (a PFX file may contain more than one certificate.)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CertStore")
set certStore = Server.CreateObject("Chilkat.CertStore")

' The 1st argument is the filename, the 2nd arg is the 
' PFX file's password:
success = certStore.LoadPfxFile("chilkat.pfx","test")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( certStore.LastErrorText) & "</pre>"
    Response.End
End If

' cert is a Chilkat.Cert
Set cert = certStore.FindCertBySubject("Chilkat Software, Inc.")
If (certStore.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( certStore.LastErrorText) & "</pre>"
    Response.End
End If

' pkey is a Chilkat.PrivateKey
Set pkey = cert.ExportPrivateKey()
If (cert.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( cert.LastErrorText) & "</pre>"

    Response.End
End If

' Get the private key in XML format:
pkeyXml = pkey.GetXml()

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa = Server.CreateObject("Chilkat.Rsa")

' Import the private key into the RSA component:
success = rsa.ImportPrivateKey(pkeyXml)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rsa.LastErrorText) & "</pre>"

    Response.End
End If

' Encode the signature as a hex string
rsa.EncodingMode = "hex"

strData = "This is the string to be signed."

' Sign the string using the sha-1 hash algorithm.
' Other valid choices are "sha-256", "md2" and "md5".
hexSig = rsa.SignStringENC(strData,"sha-1")

Response.Write "<pre>" & Server.HTMLEncode( hexSig) & "</pre>"

Response.Write "<pre>" & Server.HTMLEncode( "Success!") & "</pre>"

%>
</body>
</html>