Classic ASP

RSA SHA256 Signature using Private Key from Java Keystore

Signs plaintext using RSA SHA256 using a key from a Java keystore.

Duplicatest this code:

KeyStore keystore; // key repository for keys containing signature certificate
String alias; // alias for the certificate in the key repository
String password; // password for the certificate's private key
String plaintext; // text being signed


Signature signature = Signature.getInstance("SHA256withRSA");
signature.initSign((PrivateKey) keystore.getKey(alias, password.toCharArray()));
signature.update(plaintext.getBytes("UTF-8"));
byte[] rsa_text= signature.sign();

Chilkat Classic ASP Downloads

Download Chilkat for Classic ASP

Classic ASP

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set jks = Server.CreateObject("Chilkat.JavaKeyStore")

jksPassword = "secret"

' Load the Java keystore from a file.  The JKS file password is used
' to verify the keyed digest that is found at the very end of the keystore.
' It verifies that the keystore has not been modified.
success = jks.LoadFile(jksPassword,"qa_data/jks/sample_secret.jks")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( jks.LastErrorText) & "</pre>"
    Response.End
End If

' Get the private key from the JKS.
' The private key password may be different than the file password.
privKeyPassword = "secret"
caseSensitive = 0
set privKey = Server.CreateObject("Chilkat.PrivateKey")
success = jks.PrivateKeyOf(privKeyPassword,"some.alias",caseSensitive,privKey)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( jks.LastErrorText) & "</pre>"
    Response.End
End If

' Establish the RSA object and tell it to use the private key..
set rsa = Server.CreateObject("Chilkat.Rsa")

success = rsa.UsePrivateKey(privKey)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( rsa.LastErrorText) & "</pre>"
    Response.End
End If

' Indicate we'll be signing the utf-8 byte representation of the string..
rsa.Charset = "utf-8"

' Sign some plaintext using RSA-SHA256

plaintext = "this is the text to be signed"
binarySignature = rsa.SignString(plaintext,"SHA256")
If (rsa.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( rsa.LastErrorText) & "</pre>"
    Response.End
End If

' Alternatively, if the signature is desired in some encoded string form,
' such as base64, base64-url, hex, etc.
rsa.EncodingMode = "base64-url"
signatureStr = rsa.SignStringENC(plaintext,"SHA256")
Response.Write "<pre>" & Server.HTMLEncode( "base64-url RSA signature: " & signatureStr) & "</pre>"

%>
</body>
</html>