(Classic ASP) Duplicating OpenSSL rsautl (creating RSA signatures)

Demonstrates how to duplicate OpenSSL rsautil RSA signatures.

The Chilkat RSA component's methods for creating RSA signatures (SignBytes, SignBytesENC, SignString, and SignStringENC) are very different from OpenSSL's rsautl command. First, we'll explain what Chilkat's signing methods do, and then what OpenSSL's rsautl does. New signing methods have been added to Chilkat RSA to duplicate OpenSSL rsautl: OpenSslSignBytes, OpenSslSignBytesENC, OpenSslSignString, and OpenSslSignStringENC.

Here's what Chilkat's RSA Sign* methods do:
(Note: Chilkat RSA's Sign* methods generate signatures according to RSA Laboratories' "PKCS #1 v2.0: RSA Cryptography Standard".)

Input data is hashed using the hashing algorithm specified.
The hash is padded using either PKCS1 v1.5 or PKCS1 PSS padding. PKCS v1.5 involves encoding to ASN.1 before padding.
The padded hash is finally RSA signed (i.e. modular exponentiation) and the signature is returned.

OpenSSL rsautl is very different. Here's what it does:

The input data is not hashed. It must be a small enough amount of data such that it can be padded and signed. PKCS v1.5 padding is always used. The data is not ASN.1 encoded before padding.
The PKCS v1.5 padded data is RSA signed and the signature is returned.

The new OpenSsl* methods are designed to duplicate OpenSSL's rsautil signature functionality.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PrivateKey")
set pkey = Server.CreateObject("Chilkat.PrivateKey")

' Load the private key from an RSA PEM file:
success = pkey.LoadPemFile("private.pem")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( pkey.LastErrorText) & "</pre>"
    Response.End
End If

' Get the private key in XML format:
pkeyXml = pkey.GetXml()

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa = Server.CreateObject("Chilkat.Rsa")

' Import the private key into the RSA component:
success = rsa.ImportPrivateKey(pkeyXml)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rsa.LastErrorText) & "</pre>"
    Response.End
End If

' This example will sign a string, and receive the signature
' in a hex-encoded string.  Therefore, set the encoding mode
' to "hex":
rsa.EncodingMode = "hex"

strData = "secret"

' Create an OpenSSL style signature:
hexSig = rsa.OpenSslSignStringENC(strData)

Response.Write "<pre>" & Server.HTMLEncode( hexSig) & "</pre>"

' Recover the data using the corresponding public key:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PublicKey")
set pubkey = Server.CreateObject("Chilkat.PublicKey")

' Load the public key from a PEM file:
success = pubkey.LoadFromFile("public.pem")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( pubkey.LastErrorText) & "</pre>"
    Response.End
End If

' Get the public key in XML format:
pubkeyXml = pubkey.GetXml()

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa2 = Server.CreateObject("Chilkat.Rsa")

' Import the public key into the RSA component:
success = rsa2.ImportPublicKey(pubkeyXml)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rsa2.LastErrorText) & "</pre>"
    Response.End
End If

rsa2.EncodingMode = "hex"

' Recover the original data.

originalData = rsa2.OpenSslVerifyStringENC(hexSig)

Response.Write "<pre>" & Server.HTMLEncode( originalData) & "</pre>"

%>
</body>
</html>