Classic ASP
RSA-OAEP with SHA256 hashing

RSA encrypt a SHA256 hash with OAEP padding.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set pubkey = Server.CreateObject("Chilkat.PublicKey")

set sbPem = Server.CreateObject("Chilkat.StringBuilder")
bCrlf = 1
success = sbPem.AppendLine("-----BEGIN PUBLIC KEY-----",bCrlf)
success = sbPem.AppendLine("MIIBIjANBgkqhkiG9w0BAQEFAAOCAQ8AMIIBCgKCAQEA33TqqLR3eeUmDtHS89qF",bCrlf)
success = sbPem.AppendLine("3p4MP7Wfqt2Zjj3lZjLjjCGDvwr9cJNlNDiuKboODgUiT4ZdPWbOiMAfDcDzlOxA",bCrlf)
success = sbPem.AppendLine("04DDnEFGAf+kDQiNSe2ZtqC7bnIc8+KSG/qOGQIVaay4Ucr6ovDkykO5Hxn7OU7s",bCrlf)
success = sbPem.AppendLine("Jp9TP9H0JH8zMQA6YzijYH9LsupTerrY3U6zyihVEDXXOv08vBHk50BMFJbE9iwF",bCrlf)
success = sbPem.AppendLine("wnxCsU5+UZUZYw87Uu0n4LPFS9BT8tUIvAfnRXIEWCha3KbFWmdZQZlyrFw0buUE",bCrlf)
success = sbPem.AppendLine("f0YN3/Q0auBkdbDR/ES2PbgKTJdkjc/rEeM0TxvOUf7HuUNOhrtAVEN1D5uuxE1W",bCrlf)
success = sbPem.AppendLine("SwIDAQAB",bCrlf)
success = sbPem.AppendLine("-----END PUBLIC KEY-----",bCrlf)

' Load the public key object from the PEM. 
success = pubkey.LoadFromString(sbPem.GetAsString())
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( pubkey.LastErrorText) & "</pre>"
    Response.End
End If

' Build a small string to encrypt
set json = Server.CreateObject("Chilkat.JsonObject")
success = json.UpdateString("example","123")
success = json.UpdateString("hello","world")
Response.Write "<pre>" & Server.HTMLEncode( json.Emit()) & "</pre>"

' This is the JSON to be RSA encrypted:  {"example":"123","hello":"world"}

' IMPORTANT: RSA encryption is only used to encrypt small amounts of data.
' RSA is only able to encrypt data to a maximum amount of your key size (2048 bits = 256 bytes) 
' minus padding / header data (11 bytes for PKCS#1 v1.5 padding, 42 bytes for OAEP).
' As a result it is often not possible to encrypt files with RSA directly. 
' RSA is also not meant for this purpose. 
' 
' If you want to encrypt more data, you can use something like:
' 1) Generate a 256-bit random keystring K
' 2) Encrypt your data with AES-CBC with K
' 3) Encrypt K with RSA
' 4) Send both to the other side 

set rsa = Server.CreateObject("Chilkat.Rsa")
rsa.PkcsPadding = 0
rsa.OaepHash = "SHA-256"
success = rsa.UsePublicKey(pubkey)
rsa.EncodingMode = "base64"

' Note: The OAEP padding uses random bytes in the padding, and therefore each time encryption happens,
' even using the same data and key, the result will be different --  but still valid.  One should not expect
' to get the same output.
bUsePrivateKey = 0
encryptedStr = rsa.EncryptStringENC(json.Emit(),bUsePrivateKey)
If (rsa.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( rsa.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "Result: " & encryptedStr) & "</pre>"

%>
</body>
</html>