(Classic ASP) RSA Encrypt RSA/ECB/OAEPWithSHA1AndMGF1Padding

Demonstrates how to RSA encrypt using RSA/ECB/OAEPWithSHA1AndMGF1Padding. Also demonstrates RSA/ECB/OAEPWithSHA-256AndMGF1Padding. Both of these terms are from Java's JCE. Note: In this context, "ECB" doesn't actually mean anything. It's a symmetric cipher mode that doesn't apply (or make sense) in this context.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa = Server.CreateObject("Chilkat.Rsa")

' First load a public key object with a public key.
' In this case, we'll load it from a file.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PublicKey")
set pubkey = Server.CreateObject("Chilkat.PublicKey")
success = pubkey.LoadFromFile("qa_data/pem/rsa_public.pem")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( pubkey.LastErrorText) & "</pre>"
    Response.End
End If

' RSA encryption is limited to small amounts of data. The limit
' is typically a few hundred bytes and is based on the key size and
' padding (OAEP vs. PKCS1_5).  RSA encryption is typically used for
' encrypting hashes or symmetric (bulk encryption algorithm) secret keys.
plainText = "Time is an illusion. Lunchtime doubly so."

' Import the public key to be used for encrypting.
success = rsa.ImportPublicKeyObj(pubkey)

' To get OAEP padding, set the OaepPadding property:
rsa.OaepPadding = 1

' To use SHA1 or SHA-256, set the OaepHash property
rsa.OaepHash = "sha256"
' for SHA1 --
rsa.OaepHash = "sha1"

' Indicate we'll want hex output
rsa.EncodingMode = "hex"

' Encrypt..
usePrivateKey = 0
encryptedStr = rsa.EncryptStringENC(plainText,usePrivateKey)
Response.Write "<pre>" & Server.HTMLEncode( encryptedStr) & "</pre>"

' -------------------------------------------------
' Now decrypt with the matching private key.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa2 = Server.CreateObject("Chilkat.Rsa")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PrivateKey")
set privKey = Server.CreateObject("Chilkat.PrivateKey")
success = privKey.LoadEncryptedPem("qa_data/pem/rsa_passwd.pem","passwd")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( privKey.LastErrorText) & "</pre>"
    Response.End
End If

success = rsa2.ImportPrivateKeyObj(privKey)

' Make sure we have the same settings used for encryption.
rsa2.OaepPadding = 1
rsa2.EncodingMode = "hex"
rsa2.OaepHash = "sha1"

originalStr = rsa2.DecryptStringENC(encryptedStr,1)

Response.Write "<pre>" & Server.HTMLEncode( originalStr) & "</pre>"

%>
</body>
</html>