(Classic ASP) RSA Encrypt/Decrypt AES Key

Demonstrates how to use RSA to protect a key for AES encryption. It can be used in this scenario: You will provide your RSA public key to any number of counterparts. Your counterpart will generate an AES key, encrypt data (or a file) using it, then encrypt the AES key using your RSA public key. Your counterpart sends you both the encrypted data and the encrypted key. Since you are the only one with access to the RSA private key, only you can decrypt the AES key. You decrypt the key, then decrypt the data using the AES key.

This example will show the entire process. (1) Generate an RSA key and save both private and public parts to PEM files. (2) Encrypt a file using a randomly generated AES encryption key. (3) RSA encrypt the AES key. (4) RSA decrypt the AES key. (5) Use it to AES decrypt the file or data.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' ------------------
' Step 1.  Generate an RSA key and save to PEM files.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa = Server.CreateObject("Chilkat.Rsa")

' Generate a 1024-bit key. 
success = rsa.GenerateKey(1024)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rsa.LastErrorText) & "</pre>"
    Response.End
End If

' Keys are exported in XML format:
pubKeyXml = rsa.ExportPublicKey()

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PublicKey")
set pubKey = Server.CreateObject("Chilkat.PublicKey")
success = pubKey.LoadFromString(pubKeyXml)
' For brevity, we are not checking the return value...
success = pubKey.SavePemFile(0,"qa_temp/pubKey.pem")

privKeyXml = rsa.ExportPrivateKey()

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PrivateKey")
set privKey = Server.CreateObject("Chilkat.PrivateKey")
success = privKey.LoadXml(privKeyXml)
success = privKey.SavePemFile("qa_temp/privKey.pem")

' Other methods exist for saving the private key in PKCS8 format,
' both encrypted and un-encrypted..

' ------------------
' Step 2.   This is the code your counterpart will run to 
' AES encrypt a file.  It generates a random AES key
' to use for the encryption.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = Server.CreateObject("Chilkat.Crypt2")

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 256

' Generate random bytes and return the random bytes
' in a hex string:
crypt.EncodingMode = "hex"
randomKey = crypt.GenRandomBytesENC(32)
Response.Write "<pre>" & Server.HTMLEncode( "AES key = " & randomKey) & "</pre>"

' Set the key.
crypt.SetEncodedKey randomKey,"hex"

' Set the IV to a known value that will be used on both sides.
' (If desired, you could generate a random IV and protect it in the same
' way as the key...)
' The length of the IV for AES is always 16 bytes, regardless of the key size.
crypt.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"

' AES Encrypt the file (the file may be any size because it will
' stream the file in/out.
success = crypt.CkEncryptFile("qa_data/hamlet.xml","qa_temp/aesEncrypted.dat")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( crypt.LastErrorText) & "</pre>"
    Response.End
End If

' ------------------
' Step 3.
' ------------------
' RSA encrypt the AES key.
' We'll pretend  your counter part has the public-key PEM file and needs
' to load it.  Therefore, we'll start with a new RSA object and load
' the public key from the PEM..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa2 = Server.CreateObject("Chilkat.Rsa")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PublicKey")
set pubKey2 = Server.CreateObject("Chilkat.PublicKey")

' For brevity, don't check the success..  
success = pubKey2.LoadFromFile("qa_temp/pubKey.pem")
pubKeyXml = pubKey2.GetXml()
success = rsa2.ImportPublicKey(pubKeyXml)

' RSA encrypt the AES key and return it as a base64 encoded string.
rsa2.EncodingMode = "base64"
bUsePrivateKey = 0
encryptedAesKey = rsa2.EncryptStringENC(randomKey,bUsePrivateKey)

' At this point, your counterpart sends you the encryptedAesKey,
' and the encrypted file.

' ------------------
' Step 4 - RSA decrypt the AES key.
' ------------------

' Start with a new RSA object and load the private key from the PEM.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rsa")
set rsa3 = Server.CreateObject("Chilkat.Rsa")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PrivateKey")
set privKey2 = Server.CreateObject("Chilkat.PrivateKey")

success = privKey2.LoadPemFile("qa_temp/privKey.pem")
privKeyXml = privKey2.GetXml()
success = rsa3.ImportPrivateKey(privKeyXml)

' The encrypted AES key is encoded using base64, so set
' our EncodingMode to "base64".
rsa3.EncodingMode = "base64"

bUsePrivateKey = 1
decryptedAesKey = rsa3.DecryptStringENC(encryptedAesKey,bUsePrivateKey)
Response.Write "<pre>" & Server.HTMLEncode( "decryptedAesKey = " & decryptedAesKey) & "</pre>"

' ------------------
' Step 5 - AES decrypt the file.
' ------------------

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt2 = Server.CreateObject("Chilkat.Crypt2")

crypt2.CryptAlgorithm = "aes"
crypt2.CipherMode = "cbc"
crypt2.KeyLength = 256

' Set the key.
crypt2.SetEncodedKey decryptedAesKey,"hex"

' Set the IV 
crypt2.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"

' AES Decrypt the file (the file may be any size because it will
' stream the file in/out.
success = crypt2.CkDecryptFile("qa_temp/aesEncrypted.dat","qa_temp/decrypted.xml")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( crypt2.LastErrorText) & "</pre>"
    Response.End
End If


%>
</body>
</html>