Classic ASP
Royal Mail OBA Web Service -- Get Accounts

Royal Mail OBA Web Service -- Get Accounts.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------

' Create the following XML:

' <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:epro="urn:schemas-royalmail-com/webservice/epro">
'    <soapenv:Header>
'       <epro:Authentication>
'          <epro:Username>my_username</epro:Username>
'          <epro:Password>my_password</epro:Password>
'          <epro:AccessCode>my_accessCode</epro:AccessCode>
'          <epro:Version>1.0</epro:Version>
'          <epro:SecurityToken>mysecuritytoken</epro:SecurityToken>
'       </epro:Authentication>
'    </soapenv:Header>
'    <soapenv:Body>
'       <epro:GetAccounts/>
'    </soapenv:Body>
' </soapenv:Envelope>

set xml = Server.CreateObject("Chilkat.Xml")
xml.EmitXmlDecl = 0
xml.Tag = "soapenv:Envelope"
success = xml.AddAttribute("xmlns:soapenv","http://schemas.xmlsoap.org/soap/envelope/")
success = xml.AddAttribute("xmlns:epro","urn:schemas-royalmail-com/webservice/epro")

' Replace my_username, my_password, and my_accessCode with your actual values.  Do not replace "mysecuritytoken".
xml.UpdateChildContent "soapenv:Header|epro:Authentication|epro:Username","my_username"
xml.UpdateChildContent "soapenv:Header|epro:Authentication|epro:Password","my_password"
xml.UpdateChildContent "soapenv:Header|epro:Authentication|epro:AccessCode","my_accessCode"
xml.UpdateChildContent "soapenv:Header|epro:Authentication|epro:Version","1.0"

' Literally use the string "mysecuritytoken" here.
xml.UpdateChildContent "soapenv:Header|epro:Authentication|epro:SecurityToken","mysecuritytoken"
xml.UpdateChildContent "soapenv:Body|epro:GetAccounts",""

set http = Server.CreateObject("Chilkat.Http")

http.SetRequestHeader "SOAPAction","urn:schemas-royalmail-com/webservice/epro/GetAccounts"

' Use the sandbox endpoint:   http://interfaces.oba-v.royalmail.com/legacyws/EProImport.asmx 
' The live endpoint would be: http://www.epro.royalmail.com/WebServices/import/eproimport.asmx
endpointUrl = "http://interfaces.oba-v.royalmail.com/legacyws/EProImport.asmx"

set resp = Server.CreateObject("Chilkat.HttpResponse")
success = http.HttpStr("POST",endpointUrl,xml.GetXml(),"utf-8","text/xml",resp)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "response status code = " & resp.StatusCode) & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( resp.BodyStr) & "</pre>"

' The response looks like this:

' <?xml version="1.0" encoding="utf-8"?>
' <SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:SOAP-ENC="http://schemas.xmlsoap.org/soap/encoding/" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
'     <SOAP-ENV:Header/>
'     <SOAP-ENV:Body>
'         <ns1:GetAccountsResponse xmlns:ns1="urn:schemas-royalmail-com/webservice/epro">
'             <ns1:GetAccountsResult>
'                 <ns1:Accounts>
'                     <ns1:Account AccountName="DEMO CUSTOMER_Atos" AccountNumber="099986000"/>
'                     <ns1:Account AccountName="CREDIT MANAGEMENT CENTRE" AccountNumber="999386001"/>
'                 </ns1:Accounts>
'             </ns1:GetAccountsResult>
'         </ns1:GetAccountsResponse>
'     </SOAP-ENV:Body>
' </SOAP-ENV:Envelope>
' 

success = xml.LoadXml(resp.BodyStr)

i = 0
numAccounts = xml.NumChildrenHavingTag("SOAP-ENV:Body|ns1:GetAccountsResponse|ns1:GetAccountsResult|ns1:Accounts|ns1:Account")
Do While i < numAccounts
    xml.I = i
    accountName = xml.ChilkatPath("SOAP-ENV:Body|ns1:GetAccountsResponse|ns1:GetAccountsResult|ns1:Accounts|ns1:Account[i]|(AccountName)")
    accountNumber = xml.ChilkatPath("SOAP-ENV:Body|ns1:GetAccountsResponse|ns1:GetAccountsResult|ns1:Accounts|ns1:Account[i]|(AccountNumber)")
    Response.Write "<pre>" & Server.HTMLEncode( accountName & ": " & accountNumber) & "</pre>"
    i = i + 1
Loop

%>
</body>
</html>