Classic ASP
REST through SOCKS Proxy

Demonstrates how to connect through a SOCKS proxy to make REST API calls.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example connects to a REST server through a SOCKS proxy.
' It will connect to the Amazon AWS service for this example.
set rest = Server.CreateObject("Chilkat.Rest")
set socket = Server.CreateObject("Chilkat.Socket")

' Set the SOCKS proxy domain or IP address, port, and SOCKS version number (4 or 5)
socket.SocksHostname = "192.168.1.100"
socket.SocksPort = 1080
socket.SocksVersion = 5
' Other properties exist for specifying a SOCKS proxy login and password,
' but these are not used in this example.

' Connect through the HTTP proxy to the Amazon AWS server for the S3 service.
bTls = 1
port = 443
maxWaitMs = 5000
success = socket.Connect("s3.amazonaws.com",port,bTls,maxWaitMs)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( "Connect Failure Error Code: " & socket.ConnectFailReason) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( socket.LastErrorText) & "</pre>"
    Response.End
End If

' Use the proxied TLS connection:
success = rest.UseConnection(socket,1)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rest.LastErrorText) & "</pre>"
    Response.End
End If

' Provide AWS credentials for the REST call.
set authAws = Server.CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"
success = rest.SetAuthAws(authAws)

' List all buckets for the account...
responseXml = rest.FullRequestNoBody("GET","/")
If (rest.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rest.LastErrorText) & "</pre>"
    Response.End
End If

set xml = Server.CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseXml)

' Show the full XML returned.
Response.Write "<pre>" & Server.HTMLEncode( xml.GetXml()) & "</pre>"

' Iterate over the buckets, showing each bucket name.
success = xml.FindChild2("Buckets")
If (xml.FirstChild2() = 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( xml.GetChildContent("Name")) & "</pre>"
    Do While (xml.NextSibling2() = 1)
        Response.Write "<pre>" & Server.HTMLEncode( xml.GetChildContent("Name")) & "</pre>"
    Loop
End If

' Move the internal pointer back to the root node.
xml.GetRoot2 

%>
</body>
</html>