(Classic ASP) POP3 SSL - Read POP3 Email over TLS/SSL on Port 995

Demonstrates how to connect via TLS/SSL to a POP3 server and read email. This assumes that the POP3 server supports SSL.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for receiving (POP3) 
' and sending (SMTP) email.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = Server.CreateObject("Chilkat.MailMan")

' Set the POP3 server's hostname
mailman.MailHost = "pop.gmail.com"

' Set the POP3 login/password.
mailman.PopUsername = "****@gmail.com"
mailman.PopPassword = "****"

' Indicate that we want TLS/SSL.  Also, set the port to 995:
mailman.MailPort = 995
mailman.PopSsl = 1

' bundle is a Chilkat.EmailBundle
Set bundle = mailman.CopyMail()
If (mailman.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( mailman.LastErrorText) & "</pre>"
    Response.End
End If

i = 0

Do While i < bundle.MessageCount
    ' email is a Chilkat.Email
    Set email = bundle.GetEmail(i)

    ' Display the From email address and the subject.
    Response.Write "<pre>" & Server.HTMLEncode( "From: " & email.From) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( "Subject: " & email.Subject) & "</pre>"

    i = i + 1
Loop


%>
</body>
</html>