(Classic ASP) POP3 Session Log

Demonstrates how the Chilkat email component keeps a log of the current POP3 session in the mailman.Pop3SessionLog property.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for receiving (POP3) 
' and sending (SMTP) email.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = Server.CreateObject("Chilkat.MailMan")

' Set the POP3 server's hostname
mailman.MailHost = "pop3.example.com"

' Set the POP3 login/password.
mailman.PopUsername = "pop3_login"
mailman.PopPassword = "pop3_password"
mailman.MailPort = 995
mailman.PopSsl = 1

' You may explicitly begin and end POP3 sessions by calling
' Pop3BeginSession and Pop3EndSession.  However, 
' if a method is called that requires a connection to the POP3
' server, the connection and session will become established
' automatically.  Therefore, it is not required to explicitly call
' Pop3BeginSession and Pop3EndSession.  

success = mailman.Pop3BeginSession()
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( mailman.LastErrorText) & "</pre>"
    Response.End
End If

' Get a list of the UIDLs for the email in the mailbox and print it.
' sa is a Chilkat.StringArray
Set sa = mailman.GetUidls()
i = 0
n = sa.Count
Do While i < n
    Response.Write "<pre>" & Server.HTMLEncode( sa.GetString(i)) & "</pre>"
    i = i + 1
Loop

' Examine the POP3 session log:
Response.Write "<pre>" & Server.HTMLEncode( mailman.Pop3SessionLog) & "</pre>"

' A sample session log:

' **** Connected to pop.example.com:995
' < +OK Dovecot ready.
' > USER ****
' < +OK
' > PASS ****
' < +OK Logged in.
' > UIDL
' < +OK
' 1 UID8226-1490455265
' 2 UID8248-1490455265
' 3 UID8624-1490455265
' 4 UID8655-1490455265
' 5 UID8706-1490455265
' 6 UID9003-1490455265
' 7 UID9204-1490455265
' 8 UID9309-1490455265
' 9 UID9311-1490455265
' 10 UID9356-1490455265
' 11 UID9802-1490455265
' 12 UID10373-1490455265
' 13 UID10543-1490455265
' 14 UID10548-1490455265
' 15 UID10558-1490455265
' 16 UID10567-1490455265
' 17 UID10573-1490455265
' .

success = mailman.Pop3EndSession()
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( mailman.LastErrorText) & "</pre>"
    Response.End
End If


%>
</body>
</html>