(Classic ASP) Read All Email from POP3 Inbox by Message Numbers

Demonstrates how to read all of the email from a POP3 inbox by fetching each email by it's message number.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = Server.CreateObject("Chilkat.MailMan")

' Set the POP3 server's hostname
mailman.MailHost = "pop.someMailServer.com"

' Set the POP3 login/password.
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

' Get the number of messages in the mailbox.
numMessages = mailman.GetMailboxCount()

' Message numbers are specific to a POP3 session. 
' If a maildrop (i.e. inbox)  contains 10 messages, 
' the message numbers will be 1, 2, 3, ... 10. 
' If message number 1 is deleted and a new POP3 session 
' is established, there will be 9 messages numbered 1, 2, 3, ... 9. 

i = 1

Do While i <= numMessages

    ' email is a Chilkat.Email
    Set email = mailman.FetchByMsgnum(i)
    If (mailman.LastMethodSuccess <> 1) Then
        Response.Write "<pre>" & Server.HTMLEncode( mailman.LastErrorText) & "</pre>"
        Response.End
    End If

    Response.Write "<pre>" & Server.HTMLEncode( email.From & ": " & email.Subject & vbLf) & "</pre>"

    i = i + 1

Loop

%>
</body>
</html>