Classic ASP

PKCS7 Sign Text using RSA 2048, SHA256, Base64 Output

Demonstrates how to sign text using 2048-bit RSA with SHA256, producing PKCS#7 output in Base64. The certificate w/ private key used for signing is loaded from a .p12/.pfx file.

Chilkat Classic ASP Downloads

Download Chilkat for Classic ASP

Classic ASP

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set cert = Server.CreateObject("Chilkat.Cert")

' Load the cert and private key.  Whatever the private key happens to be,
' such as RSA or ECC, then Chilkat will use it.  If the private key is 
' a 2048-bit RSA key, then that's what will be used..
success = cert.LoadPfxFile("qa_data/pfx/myCertAndKey.p12","password")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( cert.LastErrorText) & "</pre>"
    Response.End
End If

set crypt = Server.CreateObject("Chilkat.Crypt2")

success = crypt.SetSigningCert(cert)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( crypt.LastErrorText) & "</pre>"
    Response.End
End If

' Use SHA-256
crypt.HashAlgorithm = "sha256"

' Hash the utf-8 byte representation of the string
crypt.Charset = "utf-8"

' Return the result in base64
crypt.EncodingMode = "base64"

' Sign some text..
textToSign = "This is the text to be hashed and signed."
sigBase64 = crypt.OpaqueSignStringENC(textToSign)
If (crypt.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( crypt.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( sigBase64) & "</pre>"

' The result:
' MIIS2wYJKoZIhvcNAQc ... zGeeY4Oxg==

%>
</body>
</html>