Classic ASP
OpenAI (ChatGPT) Create Image

Show how to send a POST to create an image. Gets the JSON response with URLs and then downloads images to files.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = Server.CreateObject("Chilkat.Http")

' Implements the following CURL command:

' curl https://api.openai.com/v1/images/generations \
'   -H "Content-Type: application/json" \
'   -H "Authorization: Bearer $OPENAI_API_KEY" \
'   -d '{
'     "prompt": "A cute baby sea otter",
'     "n": 2,
'     "size": "1024x1024"
'   }'

' Use the following online tool to generate HTTP code from a CURL command
' Convert a cURL Command to HTTP Source Code

' Use this online tool to generate code from sample JSON:
' Generate Code to Create JSON

' The following JSON is sent in the request body.

' {
'   "prompt": "A cute baby sea otter",
'   "n": 2,
'   "size": "1024x1024"
' }

set json = Server.CreateObject("Chilkat.JsonObject")
success = json.UpdateString("prompt","A cute baby sea otter")
success = json.UpdateInt("n",2)
success = json.UpdateString("size","1024x1024")

' Adds the "Authorization: Bearer $OPENAI_API_KEY" header.
' This is NOT a real key.  Change the "sk-vi...." to your own key.
http.AuthToken = "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"

set resp = Server.CreateObject("Chilkat.HttpResponse")
success = http.HttpJson("POST","https://api.openai.com/v1/images/generations",json,"application/json",resp)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

set sbResponseBody = Server.CreateObject("Chilkat.StringBuilder")
success = resp.GetBodySb(sbResponseBody)

set jResp = Server.CreateObject("Chilkat.JsonObject")
success = jResp.LoadSb(sbResponseBody)
jResp.EmitCompact = 0

Response.Write "<pre>" & Server.HTMLEncode( "Response Body:") & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( jResp.Emit()) & "</pre>"

respStatusCode = resp.StatusCode
Response.Write "<pre>" & Server.HTMLEncode( "Response Status Code = " & respStatusCode) & "</pre>"
If (respStatusCode >= 400) Then
    Response.Write "<pre>" & Server.HTMLEncode( "Response Header:") & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( resp.Header) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( "Failed.") & "</pre>"
    Response.End
End If

' Sample JSON response:
' (Sample code for parsing the JSON response is shown below)

' {
'   "created": 1589478378,
'   "data": [
'     {
'       "url": "https://..."
'     },
'     {
'       "url": "https://..."
'     }
'   ]
' }

' Sample code for parsing the JSON response...
' Use the following online tool to generate parsing code from sample JSON:
' Generate Parsing Code from JSON

set sbLocalFilePath = Server.CreateObject("Chilkat.StringBuilder")

' Download each image..
http.ClearHeaders 
http.AuthToken = ""

created = jResp.IntOf("created")
i = 0
count_i = jResp.SizeOfArray("data")
Do While i < count_i
    jResp.I = i
    url = jResp.StringOf("data[i].url")

    success = sbLocalFilePath.SetString("c:/aaworkarea/image_")
    success = sbLocalFilePath.AppendInt(i + 1)
    success = sbLocalFilePath.Append(".png")

    success = http.Download(url,sbLocalFilePath.GetAsString())
    If (success = 0) Then
        Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
        Response.End
    End If

    i = i + 1
Loop

%>
</body>
</html>