Classic ASP
MyInvois Malaysia Submit Document

Demonstrates how to submit a document to MyInvois.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = Server.CreateObject("Chilkat.Http")

' The following JSON is sent in the request body.

' {
'   "documents": [
'     {
'       "format": "XML",
'       "documentHash": "<SHA256_hash_of_document>",
'       "codeNumber": "INV12345",
'       "document": "<Document_encoded_in_Base64>"
'     }
'   ]
' }

' Load the document to be sent.
set sbXmlDoc = Server.CreateObject("Chilkat.StringBuilder")
success = sbXmlDoc.LoadFile("c:/invoices/invoice1.xml","utf-8")

' The MyInvois online documentation neglects to tell us the encoding of the documentHash.
' Should it be base64?  Or hex?  We can only guess.  MyInvois provides no samples,
' and omits these crucial details which are needed for actual implementation.
' 
' *** Note: It was confirmed that "hex" is the encoding that is needed.
sha256 = sbXmlDoc.GetHash("sha256","hex","utf-8")

set sbEncoded = Server.CreateObject("Chilkat.StringBuilder")
success = sbEncoded.AppendSb(sbXmlDoc)
success = sbEncoded.Encode("base64","utf-8")

set json = Server.CreateObject("Chilkat.JsonObject")
success = json.UpdateString("documents[0].format","XML")
success = json.UpdateString("documents[0].documentHash",sha256)
success = json.UpdateString("documents[0].codeNumber","INV12345")
success = json.UpdateSb("documents[0].document",sbEncoded)

' Adds the "Authorization: Bearer <access_token>" header.
http.AuthToken = "<access_token>"

set resp = Server.CreateObject("Chilkat.HttpResponse")
success = http.HttpJson("POST","https://preprod-api.myinvois.hasil.gov.my/api/v1.0/documentsubmissions",json,"application/json",resp)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "response status code = " & resp.StatusCode) & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( resp.BodyStr) & "</pre>"

%>
</body>
</html>