(Classic ASP) Verify Email Recipients

A way to possibly determine valid/invalid email addresses. I would recommend being very careful about doing this because your IP address may be flagged as a potential spammer by the mail server (because you are probing for valid/invalid email addresses). This Chilkat functionality existed for many years, before this kind of activity became a problem. The functionality remains only because it is useful for some to test with their own SMTP servers.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = Server.CreateObject("Chilkat.MailMan")

' SMTP connection settings...
mailman.SmtpHost = "smtp.example.com"
mailman.SmtpUsername = "MY_SMTP_USERNAME"
mailman.SmtpPassword = "MY_SMTP_PASSWORD"
mailman.SmtpSsl = 1
mailman.SmtpPort = 465

' Create a new email object
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = Server.CreateObject("Chilkat.Email")

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "myemail@example.com"
success = email.AddTo("person1","person1@example.com")
success = email.AddTo("person2","person2@example.com")
success = email.AddTo("person3","person3@example.com")
' The SMTP server smtp.example.com won't know anything about an email address @somewhere_else.com
success = email.AddTo("person3","person4@somewhere_else.com")
' ...

' Verify recipients.
' **** See the warning about using this API method in the description above.
' (An SMTP server only knows valid email address for its own domain.  For example,
' smtp.example.com *may* only know if person1@example.com is valid or invalid, but does
' not know anything about the validity of email addresses having other domains.)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringArray")
set badAddrs = Server.CreateObject("Chilkat.StringArray")
success = mailman.VerifyRecips(email,badAddrs)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( mailman.LastErrorText) & "</pre>"
    Response.End
End If

i = 0
Do While i < badAddrs.Count
    Response.Write "<pre>" & Server.HTMLEncode( badAddrs.GetString(i)) & "</pre>"
    i = i + 1
Loop

Response.Write "<pre>" & Server.HTMLEncode( "done.") & "</pre>"

%>
</body>
</html>