(Classic ASP) Convert Java KeyStore to PEM

Loads a Java keystore file and saves the trusted certificate entries to a PEM file.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set jks = Server.CreateObject("Chilkat.JavaKeyStore")

jksPassword = "myJksPassword"

' Load the Java keystore from a file.  The JKS file password is used
' to verify the keyed digest that is found at the very end of the keystore.
' It verifies that the keystore has not been modified.
success = jks.LoadFile(jksPassword,"/someDir/keyStore.jks")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( jks.LastErrorText) & "</pre>"
    Response.End
End If

' Open/create the output PEM file. 
' This example uses Chilkat's file access class for writing the output file.
' You may replace the file I/O lines of code with whatever is most convenient for you.
set fac = Server.CreateObject("Chilkat.FileAccess")
success = fac.OpenForWrite("/pemFiles/caCerts.pem")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( fac.LastErrorText) & "</pre>"
    Response.End
End If

numCerts = jks.NumTrustedCerts

set cert = Server.CreateObject("Chilkat.Cert")

' Iterate over the trusted certs, get the PEM for each,
' and append it to the output file.
i = 0
Do While i < numCerts
    success = jks.TrustedCertAt(i,cert)

    ' Get the certificate in PEM format.  
    pem = cert.ExportCertPem()

    ' Append the PEM string to the open file.
    success = fac.AppendText(pem,"utf-8")
    If (success <> 1) Then
        Response.Write "<pre>" & Server.HTMLEncode( fac.LastErrorText) & "</pre>"
        Response.End
    End If

    i = i + 1
Loop

' Close the output file.
fac.FileClose 

Response.Write "<pre>" & Server.HTMLEncode( "Trusted certificates saved to PEM.") & "</pre>"

%>
</body>
</html>