(Classic ASP) Process New Email by Scanning for Senders

Scan email and save application-selected emails to EML files with unique filenames.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Imap")
set imap = Server.CreateObject("Chilkat.Imap")

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.someMailServer.com")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( imap.LastErrorText) & "</pre>"
    Response.End
End If

' Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( imap.LastErrorText) & "</pre>"
    Response.End
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( imap.LastErrorText) & "</pre>"
    Response.End
End If

' We can choose to fetch UIDs or sequence numbers.
fetchUids = 1

' Fetch messages from the mailbox using a search criteria.
' This example finds NEW emails: these are emails that have the RECENT flag set, but not the SEEN flag:
' messageSet is a Chilkat.MessageSet
Set messageSet = imap.Search("NEW",fetchUids)
If (imap.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( imap.LastErrorText) & "</pre>"
    Response.End
End If

' This example will download headers, and then download
' the full email for those emails sent from a contact
' in our database.

' When downloading headers, each email object contains
' (obviously) the headers, but the body will be missing.
' Also, attachments will not be included.  However, it is
' possible to get information about the attachments
' as well as the complete size of the email.

' bundle is a Chilkat.EmailBundle
Set bundle = imap.FetchHeaders(messageSet)
If (imap.LastMethodSuccess = 0) Then

    Response.Write "<pre>" & Server.HTMLEncode( imap.LastErrorText) & "</pre>"
    Response.End
End If

' Loop over the email objects...
i = 0
numEmails = bundle.MessageCount
Do While i < numEmails
    ' email is a Chilkat.Email
    Set email = bundle.GetEmail(i)

    ' The sender's email address and name are available
    ' in the From, FromAddress, and FromName properties.
    ' If the sender is "Chilkat Support <support@chilkatsoft.com",
    ' then the From property will hold the entire string.
    ' the FromName property contains"Chilkat Support",
    ' and the FromAddress property contains "support@chilkatsoft.com"
    Response.Write "<pre>" & Server.HTMLEncode( email.From) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( email.FromAddress) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( email.FromName) & "</pre>"

    ' Assume at this point your code checks to see if the sender
    ' is one in your contacts database.  If so, this is
    ' the code you would write to download the entire
    ' email and save it to a file.

    ' The ckx-imap-uid header field is added when
    ' headers are downloaded.  This makes it possible
    ' to get the UID from the email object.
    uidStr = email.GetHeaderField("ckx-imap-uid")
    uid = CLng(uidStr)

    ' fullEmail is a Chilkat.Email
    Set fullEmail = imap.FetchSingle(uid,1)
    If (imap.LastMethodSuccess = 1) Then
        ' You may use the GenerateFilename method to
        ' generate a unique filename...

        filename = fullEmail.GenerateFilename()

        ' SaveEml saves the entire email, including attachments.
        success = fullEmail.SaveEml(filename)

    End If

    Response.Write "<pre>" & Server.HTMLEncode( "--") & "</pre>"

    i = i + 1
Loop

' Disconnect from the IMAP server.
success = imap.Disconnect()


%>
</body>
</html>