Add URL to Del.icio.us via HTTPS API

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Add a new URL to del.icio.us.

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
set http = Server.CreateObject("Chilkat_9_5_0.Http")

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    Response.Write http.LastErrorText & "<br>"

End If

'  del.icio.us uses HTTP-Auth, which means you only need
'  to set your login/password here:
http.Login = "chilkatsoft"
http.Password = "MyPassword"

'  Create a request and add the info:
set req = Server.CreateObject("Chilkat_9_5_0.HttpRequest")
req.AddParam "url","http://www.chilkatsoft.com/"
req.AddParam "description","Chilkat Software, Inc."
req.AddParam "tags","chilkat components activex library software"

'  There are other optional params that can be added,
'  but we'll skip those.  More information is at:
'  http://del.icio.us/help/api/posts

'  Indicate the HTTP method desired (POST or GET)
req.UseGet 

'  The path is: /v1/posts/add
req.Path = "/v1/posts/add"

'  Notice that the URL is this:
'  https://api.del.icio.us/v1/posts/add?....
' 
'  The domain = api.del.icio.us
'  We're using HTTPS, so the port = 443, and we set the SSL argument to true (below)
'  The "path" part of the URL is "/v1/posts/add"

'  Send the HTTPS GET and get the response.  Note: This is a blocking call.
'  The method does not return until the full HTTPS response is received.

domain = "api.del.icio.us"
port = 443
ssl = 1

Set resp = http.SynchronousRequest(domain,port,ssl,req)
If (resp Is Nothing ) Then
    Response.Write http.LastErrorText & "<br>"
Else
    '  Check the XML returned:
    '  We should have a <result code="done" />
    Response.Write resp.BodyStr & "<br>"
End If


%>
</body>
</html>