(Classic ASP) Send XMLHttpRequest using PUT, GET, DELETE, or any HTTP Request Method

The PostXml method is the easiest way to send an XMLHttpRequest using the POST HTTP verb (which is by far the most common). To use a different HTTP request method (such as PUT, GET, DELETE, etc.), the SynchronousRequest method should be called. It provides more flexibility in constructing the exact HTTP request desired.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = Server.CreateObject("Chilkat.Http")

' The XML sent in the body of the request is application
' specified -- it should contain whatever the server-side
' application is expecting..
xmlStr = "<?xml version=""1.0"" encoding=""UTF-8""?><appXml><something>123</something></appXml>"

' If the service endpoint is  "http://www.chilkatsoft.com/xmlEcho.asp",
' then we have the following arguments to be passed to
' SynchronousRequest:
endpointDomain = "www.chilkatsoft.com"
endpointPort = 80
endpointSsl = 0

' Prepare the HTTP request object:
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = Server.CreateObject("Chilkat.HttpRequest")
req.Path = "/xmlEcho.asp"

' This example will use the "PUT" HTTP request method
' (also known as HTTP verb)
req.HttpVerb = "PUT"
req.ContentType = "text/xml"
req.Charset = "utf-8"
success = req.LoadBodyFromString(xmlStr,"utf-8")

' resp is a Chilkat.HttpResponse
Set resp = http.SynchronousRequest(endpointDomain,endpointPort,endpointSsl,req)
If (http.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

' The raw HTTP request sent by the above call is:

' PUT /xmlEcho.asp HTTP/1.1
' Content-Type: text/xml
' Host: www.chilkatsoft.com
' Content-Length: 81
' 
' <?xml version="1.0" encoding="UTF-8"?><appXml><something>123</something></appXml>

' Examine the Body of the HTTP response
' This would be the XML response sent by the server.
Response.Write "<pre>" & Server.HTMLEncode( resp.BodyStr) & "</pre>"


%>
</body>
</html>