Classic ASP
HTTP - Verify Server is a Trusted Root CA

Demonstrates how to only allow connections to an HTTP server having a certificate with a root that is in our list of trusted CA root certificates.
Chilkat Classic ASP Downloads

Download Chilkat for Classic ASP
Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

success = 0

'  On my particular system, the root CA cert for this URL is not pre-installed.
'  Note: This may be different for you.
'  Also, this example was written on 29-May-2015.  This URL was valid at the time,
'  but may not be valid at a future date.
url = "https://animals.nationalgeographic.com/animals/invertebrates/starfish/"

set http = Server.CreateObject("Chilkat.Http")

'  Require that the SSL/TLS server certificate is not expired,
'  and that the certificate signature is valid.
'  This does not ensure that it has a chain of authentication to
'  a trusted root.  To ensure that, the TrustedRoots object (below) is required.
http.RequireSslCertVerify = 1

'  Do the HTTPS page fetch (through the SSH tunnel)
html = http.QuickGetStr(url)
If (http.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "The HTTP GET was successful.") & "</pre>"

'  Now let's require that HTTP requests to SSL/TLS servers that don't have trusted CA roots
'  should fail.
set trustedRoots = Server.CreateObject("Chilkat.TrustedRoots")

'  Indicate that we will trust any pre-installed certificates on this system.
'  (The meaning of pre-installed certificates depends on the operating system, and in
'  some environments there is no such thing as pre-installed certificates.  See the reference
'  documentation for the TrustedRoots class.)
trustedRoots.TrustSystemCaRoots = 1

'  Activate the trusted roots globally for all Chilkat objects.
'  This call really shouldn't fail, so we're not checking the return value.
success = trustedRoots.Activate()

'  Given that our previous HTTP GET likely kept the connection open,
'  make sure that all HTTP connections are closed before re-trying.
'  Otherwise, we'll simply be re-using the pre-existing connection.
success = http.CloseAllConnections()

'  Now let's try fetching the URL again.  It should fail this time because
'  there is a requirement that the SSL/TLS server certificate must have a trusted root,
'  and the trusted root for this URL is not installed on my system (but may be different for you..)
html = http.QuickGetStr(url)
If (http.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( "Good, the HTTP request failed as expected.") & "</pre>"
Else
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( "Hmmm... we did not fail as expected?") & "</pre>"
End If


%>
</body>
</html>