(Classic ASP) HTTP POST with some Params in URL and others in application/x-www-form-urlencoded Body

Demonstrates show to send an HTTP POST with some params in the URL, and others in the application/x-www-form-urlencoded Body

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Imagine a URL that contains two params: one named "xyz" and one named "name".
' We want to send a POST to it, but with 2 additional params in the body of the request.
' The PostUrlEncoded method cannot be used because it parses the URL and puts all the params
' in the HTTP body.  The SynchronousRequest method should instead be used so
' that the req.Path can be explicitly specified.
url = "http://www.chilkatsoft.com/echoPost.asp?xyz=123&name=matt"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = Server.CreateObject("Chilkat.Http")

' Provide a session log path so we can visually verify the exact request sent.
' (This is only for debugging purposes.)
http.SessionLogFilename = "c:/aaworkarea/httpLog.txt"

' Create an HTTP request that has two additional params
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = Server.CreateObject("Chilkat.HttpRequest")

req.HttpVerb = "POST"
req.Path = "/echoPost.asp?xyz=123&name=matt"
req.AddParam "sport","tennis"
req.AddParam "tournament","French Open"

' Send the HTTP POST and get the response.
' resp is a Chilkat.HttpResponse
Set resp = http.SynchronousRequest("www.chilkatsoft.com",80,0,req)
If (http.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( resp.BodyStr) & "</pre>"

Response.Write "<pre>" & Server.HTMLEncode( "Success.") & "</pre>"

%>
</body>
</html>