(Classic ASP) Directory Existence Check

How to test if a directory exists on an FTP server.

A good way to check to see if a directory already exists is to try to "cd" to that remote directory by calling ChangeRemoteDir. If it succeeds, then the directory exists. If not, then it does not exist. An alternative method is to set the ListPattern = "*" and then iterate over the files/directories, looking for the directory.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Ftp2")
set ftp = Server.CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.example.com"
ftp.Username = "login"
ftp.Password = "password"

' Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
End If

' Does the "temp" directory exist?

dirExists = ftp.ChangeRemoteDir("/temp")
If (dirExists = 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( "Yes, the temp directory exists.") & "</pre>"
    '  Yes, it exists. Restore the current remote dir:
    success = ftp.ChangeRemoteDir("..")
    If (success <> 1) Then
        Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
        Response.End
    End If

End If

' Alternatively, you may set the ListPattern = "*" and 
'  look for the directory:
ftp.ListPattern = "*"

n = ftp.GetDirCount()
If (n < 0) Then
    ' Failed to get directory listing based on ListPattern
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
End If

If (n > 0) Then
    For i = 0 To n - 1

        isDir = ftp.GetIsDirectory(i)
        If (isDir = 1) Then

            fname = ftp.GetFilename(i)
            If (fname = "temp") Then
                Response.Write "<pre>" & Server.HTMLEncode( "Found temp directory!") & "</pre>"
                success = ftp.Disconnect()
                Response.End
            End If

        End If

    Next
End If

success = ftp.Disconnect()

%>
</body>
</html>