(Classic ASP) Encrypt File using X.509 Certificate using AES in CBC Mode

Demonstrates how to encrypt a file using an X.509 Certificate's public key, where the underlying bulk encryption algorithm is 128-bit AES in CBC mode. (The underlying bulk encryption algorithm can be specified to be other algorithms/strengths.)

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat Crypt API to have been previously unlocked.
' See Unlock Chilkat Crypt for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = Server.CreateObject("Chilkat.Crypt2")

' Use public-key cryptography for encryption.
crypt.CryptAlgorithm = "pki"

' Get an X.509 certificate to use for encrypting.
' Note: Chilkat provides many different ways of loading a certificate, from many different formats,
' or if on Windows, from the installed certificates on the system.
' This example simply loads a certificate from a file.
' Also, for encryption, only the public key is needed.  Digital certificates embed the public key
' within the X.509 format itself.  Therefore, if you have a certificate, you also have the public key.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = Server.CreateObject("Chilkat.Cert")
success = cert.LoadFromFile("qa_data/certs/testCert.cer")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( cert.LastErrorText) & "</pre>"
    Response.End
End If

success = crypt.SetEncryptCert(cert)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( crypt.LastErrorText) & "</pre>"
    Response.End
End If

' Indicate the underlying bulk encryption algorithm to be used:
crypt.Pkcs7CryptAlg = "aes"
crypt.KeyLength = 128

' Note: When doing public-key encryption the underlying bulk symmetric cipher mode will always be CBC. (at least with Chilkat...)

' There's one last option that could be set.  If is the RSA encryption encryption/padding scheme. 
' By default, RSAES_PKCS1-V1_5 is used.  If desired, the OaepPadding property could be set to 1 to
' use RSAES_OAEP.  (We'll leave it set at the default value of 0)
crypt.OaepPadding = 0

' Everything is specified.  Now just encrypt...
' The output is PKCS7 in binary DER format.
success = crypt.CkEncryptFile("qa_data/hamlet.xml","qa_output/hamlet.p7")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( crypt.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "Finished.") & "</pre>"

%>
</body>
</html>