(Classic ASP) Duplicate curl -u user:password with Chilkat HTTP

Demonstrates how to duplicate a curl command that uses the -u username:password option. (This assumes HTTP Basic Authentication, and Chilkat requires Basic authentication to be over a TLS connection.)

Duplicates the following curl command:

curl https://api.sandbox.paypal.com/v1/oauth2/token \
  -H "Accept: application/json" \
  -H "Accept-Language: en_US" \
  -u "Client-Id:Secret" \
  -d "grant_type=client_credentials"

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = Server.CreateObject("Chilkat.Http")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = Server.CreateObject("Chilkat.HttpRequest")

' The AddHeader method corresponds to the curl "-H" argument.
req.AddHeader "Accept","application/json"
req.AddHeader "Accept-Language","en_US"

' The curl "-d" argument specifies the HTTP request body.  In this case,
' we're sending an application/x-www-form-urlencoded request, and therefore
' the body contains the URL-encoded query parameters.
req.AddParam "grant_type","client_credentials"

http.Login = "PAYPAL_REST_API_CLIENT_ID"
http.Password = "PAYPAL_REST_API_SECRET"

' Sends a POST request where the Content-Type is application/x-www-form-urlencoded
' resp is a Chilkat.HttpResponse
Set resp = http.PostUrlEncoded("https://api.sandbox.paypal.com/v1/oauth2/token",req)
If (http.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

If (resp.StatusCode <> 200) Then
    Response.Write "<pre>" & Server.HTMLEncode( "Error status code: " & resp.StatusCode) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( resp.BodyStr) & "</pre>"

    Response.End
End If

' The JSON response is in the resp BodyStr property
Response.Write "<pre>" & Server.HTMLEncode( resp.BodyStr) & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( "-- Success.") & "</pre>"


%>
</body>
</html>