(Classic ASP) CSV Special Chars - Comma, Double-Quotes

The Chilkat CSV class/component automatically handles special characters which include double-quotes, and the delimiter character (comma or semicolon).

The Chilkat CSV library/component/class is freeware. The downloads for .NET, C++, Perl, Java, Ruby, and Python contain all of the Chilkat classes, some of which are freeware and some of which require licensing.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example program loads a file (sample.csv)
' that contains this content:
' 
' year,color,country,food
' 2001,red,France,cheese
' 2005,blue,"United States",hamburger
' 2008,green,Italy,pasta
' 1998,orange,Japan,sushi
' 
' The first row contains the column names.
' This file is available at:
' http://www.chilkatsoft.com/testData/sample.csv

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Csv")
set csv = Server.CreateObject("Chilkat.Csv")

' Prior to loading the CSV file, indicate that the 1st row
' should be treated as column names:
csv.HasColumnNames = 1

' Load the CSV records from the file:

success = csv.LoadFile("sample.csv")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( csv.LastErrorText) & "</pre>"
    Response.End
End If

' A field may contain the delimiter character (in this case
' the delimiter is a comma):
' Change "cheese" to "cheese,baguette"
' ("cheese" is at row=0, column=3
success = csv.SetCell(0,3,"cheese,baguette")

' A field may also contain double-quotes:
' Change blue to shiny "metallic" blue
success = csv.SetCell(1,1,"shiny ""metallic"" blue")

' Write the updated CSV to a string and display:

csvDoc = csv.SaveToString()
Response.Write "<pre>" & Server.HTMLEncode( csvDoc) & "</pre>"

' Save the CSV to a file:
success = csv.SaveFile("out.csv")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( csv.LastErrorText) & "</pre>"
End If

' The out.csv contains this:
' year,color,country,food
' 2001,red,France,"cheese,baguette"
' 2005,"shiny ""metallic"" blue","United States",hamburger
' 2008,green,Italy,pasta
' 1998,orange,Japan,sush

%>
</body>
</html>