(Classic ASP) Encrypting or Hashing Hex or Base64 Encoded Binary Data

This example demonstrates how to encrypt binary input data that is in an encoded string form, such as "hex" or "base64". The goal is to do the following:

Decode the input to get the binary data to be hashed or encrypted.
Hash or encrypt.
Encode the result and return as a hex or base64 encoded string.

This can be accomplished by setting the Charset property equal to the encoding of the input string. Normally, the Charset property indicates the internal character encoding representation to be used before hashing/encrypting. When set to the names of values such as "hex" or "base64", it indicates that we don't actually have text data, but simply binary data that is to be decoded first, then hashed/encrypted, and then returned (possibly as an encoded string, as shown in this example).

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = Server.CreateObject("Chilkat.Crypt2")

sHexBinary = "9D4203A3FF07791A1CD7FB0075D179E14E8B9DBEBFDE24F6D04613B8397B328E"

' The input is hex-encoded binary data, so set the Charset property = "hex"
' The Charset can also be "base64".
crypt.Charset = "hex"
' The output will be encoded to hex also.
crypt.EncodingMode = "hex"

crypt.HashAlgorithm = "ripemd160"
hash = crypt.HashStringENC(sHexBinary)
Response.Write "<pre>" & Server.HTMLEncode( "RIPEMD160: " & hash) & "</pre>"

' Important: This example requires Chilkat v9.5.0.49 or greater to work correctly.

' The same can be accomplished w/ encryption:	
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 256
crypt.PaddingScheme = 0

crypt.Charset = "hex"
crypt.EncodingMode = "hex"

ivHex = "000102030405060708090A0B0C0D0E0F"
crypt.SetEncodedIV ivHex,"hex"

keyHex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F"
crypt.SetEncodedKey keyHex,"hex"

encStr = crypt.EncryptStringENC(sHexBinary)
Response.Write "<pre>" & Server.HTMLEncode( encStr) & "</pre>"

' Important: This example requires Chilkat v9.5.0.49 or greater to work correctly.
decStr = crypt.DecryptStringENC(encStr)
Response.Write "<pre>" & Server.HTMLEncode( decStr) & "</pre>"

%>
</body>
</html>