(Classic ASP) Compress Large Binary File in Blocks

Compresses a large binary file in blocks. This example uses BeginCompressBytes, MoreCompressBytes, and EndCompressBytes.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set facSrc = Server.CreateObject("Chilkat.FileAccess")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set facDest = Server.CreateObject("Chilkat.FileAccess")

' Open a large binary file for reading.
success = facSrc.OpenForRead("qa_data/bmp/big.bmp")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( facSrc.LastErrorText) & "</pre>"
    Response.End
End If

' If we compress in 64K chunks, find out how many blocks there will be.
blockSize = 65536
numBlocks = facSrc.GetNumBlocks(blockSize)

' Open an output file for the compressed data.
success = facDest.OpenForWrite("qa_data/bmp/compressedBmp.dat")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( facDest.LastErrorText) & "</pre>"
    Response.End
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Compression")
set compress = Server.CreateObject("Chilkat.Compression")
compress.Algorithm = "deflate"

i = 0
Do While i < numBlocks
    fileBytes = facSrc.ReadBlock(i,blockSize)
    If (i = 0) Then
        compressedBytes = compress.BeginCompressBytes(fileBytes)
    Else
        compressedBytes = compress.MoreCompressBytes(fileBytes)
    End If

    success = facDest.FileWrite(compressedBytes)

    i = i + 1
Loop

' At the very end, flush any remaining compressed bytes, if any.
compressedBytes = compress.EndCompressBytes()
success = facDest.FileWrite(compressedBytes)

facSrc.FileClose 
facDest.FileClose 

Response.Write "<pre>" & Server.HTMLEncode( "Finished compressing file.") & "</pre>"

%>
</body>
</html>