(Classic ASP) Blowfish CFB Mode Encryption

Demonstrates how to encrypt using Blowfish CFB (Cipher Feedback) mode.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = Server.CreateObject("Chilkat.Crypt2")

' Use "blowfish2" to produce correct results that match published blowfish test vectors.
crypt.CryptAlgorithm = "blowfish2"
crypt.CipherMode = "cfb"
crypt.KeyLength = 256

' EncodingMode specifies the encoding of the output for
' encryption, and the input for decryption.
' It may be "hex", "url", "base64", "quoted-printable", or many other choices.
crypt.EncodingMode = "hex"

' The block size of the blowfish algoirthm is 8 bytes, therefore the IV is 8 bytes.
ivHex = "0001020304050607"
crypt.SetEncodedIV ivHex,"hex"

' The secret key must equal the size of the key.  For
' 256-bit encryption, the binary secret key is 32 bytes.
keyHex = "603deb1015ca71be2b73aef0857d77811f352c073b6108d72d9810a30914dff4"
crypt.SetEncodedKey keyHex,"hex"

' Encrypt a string...
encStr = crypt.EncryptStringENC("In all intellectual debates, both sides tend to be correct in what they affirm, and wrong in what they deny. -- John Stuart Mill")
Response.Write "<pre>" & Server.HTMLEncode( encStr) & "</pre>"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set decrypt = Server.CreateObject("Chilkat.Crypt2")

decrypt.CryptAlgorithm = "blowfish2"
decrypt.CipherMode = "cfb"
decrypt.KeyLength = 256
decrypt.EncodingMode = "hex"
decrypt.SetEncodedIV ivHex,"hex"
decrypt.SetEncodedKey keyHex,"hex"

' Now decrypt:
decStr = decrypt.DecryptStringENC(encStr)
Response.Write "<pre>" & Server.HTMLEncode( decStr) & "</pre>"

%>
</body>
</html>