Classic ASP
Azure Key Vault - Get a String Secret

Demonstrates how to fetch the content of a string secret from the Azure Key Vault.
Note: This example requires Chilkat v10.1.0 or later.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The bootstrap secret will contain the following information:

' Azure Tenant ID
' Azure Client ID
' Azure Client Secret

' See following examples for setting up a bootstrap secret in memory, 
' or in the local manager (Windows Credentials Manager or Apple Keychain)
' Setup Bootstrap Secret in Local Manager
' Setup Bootstrap Secret in Memory
set bootstrap = Server.CreateObject("Chilkat.Secrets")

' Set the location of the bootstrap secret.
' Can be "local_manager" or "memory", depending on how you setup the bootstrap secret.
' ---------------------------------------------------------------------------------------------
' If your operating system is NOT Windows or MacOS/iOS, then change "local_manager" to "memory"
' You can also, if desired, use "memory" on Windows and MacOS/iOS if your bootstrap secret was previously setup in memory.
' ---------------------------------------------------------------------------------------------
bootstrap.Location = "local_manager"

' Specify the bootstrap secret to be used.
set bsId = Server.CreateObject("Chilkat.JsonObject")
success = bsId.UpdateString("appName","azure_bs")
success = bsId.UpdateString("service","Example")
success = bsId.UpdateString("username","Joe")

' ----------------------------------------------------
set secrets = Server.CreateObject("Chilkat.Secrets")

secrets.Location = "azure_key_vault"
success = secrets.SetBootstrapSecret(bsId,bootstrap)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( secrets.LastErrorText) & "</pre>"
    Response.End
End If

' Specify the secret to be fetched.
set json = Server.CreateObject("Chilkat.JsonObject")
success = json.UpdateString("appName","Test")
success = json.UpdateString("service","Something")
success = json.UpdateString("domain","Xyz")
success = json.UpdateString("username","Abc")

' For Azure Key Vault, we also need to specify the name of the vault where the secret is located.
' Replace "kvChilkat" with the name of your key vault.
success = json.UpdateString("vaultName","kvChilkat")

' Get the secret.
secretValue = secrets.GetSecretStr(json)
If (secrets.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( secrets.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "The content of the secret: " & secretValue) & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( "Success.") & "</pre>"

%>
</body>
</html>