(Classic ASP) Async Methods Returning an String

Demonstrates how to call an asynchronous method that returns a string. This example sends an HTTPS GET request to a URL and gets the HTML response.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = Server.CreateObject("Chilkat.Http")

' task is a Chilkat.Task
Set task = http.QuickGetStrAsync("https://www.chilkatsoft.com/helloWorld.html")
If (http.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

' Start the background task.
success = task.Run()
If (Not success) Then
    Response.Write "<pre>" & Server.HTMLEncode( task.LastErrorText) & "</pre>"

    Response.End
End If

' The application is now free to do anything else

' For this example, we'll simply sleep and periodically
' check to see if the HTTPS GET if finished.
Do While task.Finished <> 1
    ' Sleep 100 ms.
    task.SleepMs 100
Loop

' A finished task could be one that was canceled, aborted, or truly finished.  

' If the task was "canceled", it was canceled prior to actually starting.  This could
' happen if the task was canceled while waiting in a thread pool queue to be scheduled by Chilkat's
' background thread pool scheduler.  

' If the task was "aborted", it indicates that it was canceled while running in a background thread.  
' The ResultErrorText will likely indicate that the task was aborted.

' If the task "completed", then it ran to completion, but the actual success/failure of the method
' is determined by the result obtained via a GetResult* method.  (A "completed" task will
' have a StatusInt equal to 7.   If the task finished, but was not completed, then it must've
' been aborted or canceled:
If (task.StatusInt <> 7) Then
    Response.Write "<pre>" & Server.HTMLEncode( "Task did not complete.") & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( "task status: " & task.Status) & "</pre>"

    Response.End
End If

' The QuickGetStr method returns a string.  Therefore, after the task is finished,
' we can get the string result by calling GetResultString.  This is the return value had
' we called QuickGetStr synchronously.
html = task.GetResultString()

Response.Write "<pre>" & Server.HTMLEncode( html) & "</pre>"


%>
</body>
</html>