(Classic ASP) Get Akeneo Token given Client ID and Secret

Assumes you're starting with a client ID and secret obtained from your OAuth1 provider, such as OneLogin. Demonstrates how to get an akeneo token using your client id/secret in combination with your akeneo login/password.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = Server.CreateObject("Chilkat.Http")

' The HTTP Basic authentication for this request is the
' OAuth client id and secret you've already obtained.
http.BasicAuth = 1
http.Login = "my_akeneo_client_id"
http.Password = "my_akeneo_secret"

' Build this JSON:
' {
'   "grant_type": "password",
'   "username": "yourusername",
'   "password": "yourpassword"
' }

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = Server.CreateObject("Chilkat.JsonObject")
success = json.UpdateString("grant_type","password")
success = json.UpdateString("username","my_akeneo_username")
success = json.UpdateString("password","my_akeneo_password")

' POST this JSON (with the Basic Authentication header)
url = "http://pim.my-akeneo-site.com/api/oauth/v1/token"
' resp is a Chilkat.HttpResponse
Set resp = http.PostJson3(url,"application/json",json)
If (http.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "Response status code: " & resp.StatusCode) & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( "Response body: " & resp.BodyStr) & "</pre>"

If (resp.StatusCode = 200) Then
    ' Success.
    ' Parse the response, which looks like this:

    ' 		{
    ' 		    "access_token": "MTE0NzNkNzI5YTk0ZTBlNmFlNTI5NmVkOWJhZjUxYWRkN2UzZWIwOWNkMTkwNzY5Mzk3NGViMDFmYzdlODJlMg",
    ' 		    "expires_in": 3600,
    ' 		    "token_type": "bearer",
    ' 		    "scope": null,
    ' 		    "refresh_token": "ZDkyMzA2NDhlZjQ2MGQyMDQ2MWRiMDBmOTdkZjQ5ODY5Mzc3MTEzMjVkNTkwZThmNWRlNWY0MzllYWMxZWQ5ZA"
    ' 		}

    success = json.Load(resp.BodyStr)
    access_token = json.StringOf("access_token")
    expires_in = json.IntOf("expires_in")
    token_type = json.StringOf("token_type")
    scope = json.StringOf("scope")
    refresh_token = json.StringOf("refresh_token")

    Response.Write "<pre>" & Server.HTMLEncode( "Access Token: " & access_token) & "</pre>"
End If


%>
</body>
</html>