(Classic ASP) Encrypting a Data Stream

This example illustrates encrypting a large dataset using symmetric encryption algorithms like AES, ChaCha20, Blowfish, etc. The data is processed in chunks using the EncryptStringENC method. The FirstChunk and LastChunk properties identify whether a chunk is the first, intermediate, or last in the encrypted stream. By default, both properties are set to 1, indicating that the data provided represents the entire dataset.

You can provide data chunks smaller than the encryption algorithm's block size. For example, AES uses 16-byte blocks; 3DES, and Blowfish use 8-byte blocks; and ChaCha20, as a streaming algorithm, effectively has a block size of 1 byte.

Chilkat handles the buffering of data as needed. If a data chunk smaller than the block size is provided, an empty string (or 0 bytes) is returned, and the data is buffered to be combined with subsequent chunks. The final chunk is padded to the algorithm's block size (as determined by the PaddingScheme property) to complete the encryption process.

Chunk-wise decryption follows the same procedure as chunk-wise encryption.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set crypt = Server.CreateObject("Chilkat.Crypt2")

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

crypt.SetEncodedKey "000102030405060708090A0B0C0D0E0F","hex"
crypt.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"

crypt.EncodingMode = "hex"
txt1 = "The quick brown fox jumped over the lazy dog." & vbCrLf
txt2 = "-" & vbCrLf
txt3 = "Done." & vbCrLf

set sbEncrypted = Server.CreateObject("Chilkat.StringBuilder")

' Encrypt the 1st chunk:
' (don't worry about feeding the data to the encryptor in 
' exact multiples of the encryption algorithm's block size.
' Chilkat will buffer the data.)
crypt.FirstChunk = 1
crypt.LastChunk = 0
success = sbEncrypted.Append(crypt.EncryptStringENC(txt1))

' Encrypt the 2nd chunk
crypt.FirstChunk = 0
crypt.LastChunk = 0
success = sbEncrypted.Append(crypt.EncryptStringENC(txt2))

' Now encrypt N more chunks...
' Remember -- we're doing this in CBC mode, so each call
' to the encrypt method depends on the state from previous
' calls...
crypt.FirstChunk = 0
crypt.LastChunk = 0

For i = 0 To 4
    success = sbEncrypted.Append(crypt.EncryptStringENC(txt1))
    success = sbEncrypted.Append(crypt.EncryptStringENC(txt2))
Next

' Now encrypt the last chunk:
crypt.FirstChunk = 0
crypt.LastChunk = 1
success = sbEncrypted.Append(crypt.EncryptStringENC(txt3))

Response.Write "<pre>" & Server.HTMLEncode( sbEncrypted.GetAsString()) & "</pre>"

' Now decrypt in one call.
' (The data we're decrypting is both the first AND last chunk.)  
crypt.FirstChunk = 1
crypt.LastChunk = 1
decryptedText = crypt.DecryptStringENC(sbEncrypted.GetAsString())

Response.Write "<pre>" & Server.HTMLEncode( decryptedText) & "</pre>"

' Note: You may decrypt in N chunks by setting the FirstChunk
' and LastChunk properties prior to calling the Decrypt* methods

%>
</body>
</html>