(Classic ASP) Adobe Analytics Reporting API (1.4)

Demonstrates a simple POST of JSON to the Adobe Analytics Reporting API (v1.4)

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' In this example, replace "rsid" with your report suite id, and update the URL to use the correct endpoint
url = "https://api.omniture.com/admin/1.4/rest/?method=Report.Queue"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = Server.CreateObject("Chilkat.JsonObject")
success = json.UpdateString("reportDescription.reportSuiteID","rsid")
success = json.UpdateString("reportDescription.dateGranularity","hour")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = Server.CreateObject("Chilkat.Http")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set dt = Server.CreateObject("Chilkat.CkDateTime")
success = dt.SetFromCurrentSystemTime()
timecreated = dt.GetAsTimestamp(0)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Prng")
set prng = Server.CreateObject("Chilkat.Prng")
nonce = prng.GenRandom(12,"hex")

secret = "SECRET"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sb = Server.CreateObject("Chilkat.StringBuilder")
success = sb.Append(nonce)
success = sb.Append(timecreated)
success = sb.Append(secret)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = Server.CreateObject("Chilkat.Crypt2")
crypt.HashAlgorithm = "sha1"
crypt.EncodingMode = "base64"
digest = crypt.HashStringENC(sb.GetAsString())

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbNonce = Server.CreateObject("Chilkat.StringBuilder")
success = sbNonce.Append(nonce)
success = sbNonce.Encode("base64")

sb.Clear 
success = sb.Append("UsernameToken Username=""USERNAME"", PasswordDigest=""")
success = sb.Append(digest)
success = sb.Append(""", Nonce=""")
success = sb.Append(sbNonce.GetAsString())
success = sb.Append(""", Created=""")
success = sb.Append(timecreated)
success = sb.Append("""")

Response.Write "<pre>" & Server.HTMLEncode( sb.GetAsString()) & "</pre>"

http.SetRequestHeader "X-WSSE",sb.GetAsString()

' resp is a Chilkat.HttpResponse
Set resp = http.PostJson2(url,"text/json",json.Emit())
If (http.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "Http Status code: " & resp.StatusCode) & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( "JSON response:") & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( resp.BodyStr) & "</pre>"


%>
</body>
</html>