(Classic ASP) 2-Key Triple DES (112 bits)

Demonstrates 2-Key Triple DES encryption (112-bit 3DES encryption).

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = Server.CreateObject("Chilkat.Crypt2")

' Specify 3DES for the encryption algorithm:
crypt.CryptAlgorithm = "3des"

crypt.CipherMode = "ecb"

' For 2-Key Triple-DES, use a key length of 128
' (Given that each byte's msb is a parity bit, the strength is really 112 bits).
crypt.KeyLength = 128

' Pad with zeros
crypt.PaddingScheme = 3

' EncodingMode specifies the encoding of the output for
' encryption, and the input for decryption.
' It may be "hex", "url", "base64", or "quoted-printable".
crypt.EncodingMode = "hex"

' Let's create a secret key by using the MD5 hash of a password.
' The Digest-MD5 algorithm produces a 16-byte hash (i.e. 128 bits)
crypt.HashAlgorithm = "md5"
keyHex = crypt.HashStringENC("secretPassword")

' Set the encryption key:
crypt.SetEncodedKey keyHex,"hex"

' Encrypt
encStr = crypt.EncryptStringENC("The quick brown fox jumped over the lazy dog")
Response.Write "<pre>" & Server.HTMLEncode( encStr) & "</pre>"

' Now decrypt:
decStr = crypt.DecryptStringENC(encStr)
Response.Write "<pre>" & Server.HTMLEncode( decStr) & "</pre>"

%>
</body>
</html>